quote:

---

Here's an example of what a member has to place in a post for just a regular YouTube video.

[youtube]XYBehBWgGPY[/youtube]

---

I wrote this mod for Snitz Forum to use a simple forum code like:

[youtube]http://www.youtube.com/watch?v=gJmX1z1NY2c[/youtube]

to embed a youtube video in the forum.

____________________________________


Modify "inc_func_common.asp" adding the following function at the end of the file, before the <script> section:



<%
Function ReplaceYouTubeTags(fString)		
 	Dim oTag, cTag
 	Dim roTag1, rcTag1, roTag2, rcTag2
 	Dim oTagPos, cTagPos
 	Dim nTagPos
 	Dim counter1, counter2, counter3
 	Dim strCodeText
 	Dim Tagcount
 	Dim strTempString, strResultString
 	TagCount = 1
  	Dim CodeTags(1,2,3)
 	Dim strArray, strArray2, strArray3, strArray4

 	CodeTags(1,1,1) = "[youtube]"
 	CodeTags(1,2,1) = "[/youtube]"
 	CodeTags(1,1,2) = "<object width=""425"" height=""353""><param name=""movie"" value=""http://www.youtube.com/v/"
 	CodeTags(1,2,2) = """></param><param name=""wmode"" value=""transparent""></param>"
	CodeTags(1,1,3) = "<embed src=""http://www.youtube.com/v/"
	CodeTags(1,2,3) = """ type=""application/x-shockwave-flash"" wmode=""transparent"" width=""425"" height=""353""></embed></object>"

 	strResultString = ""
 	strTempString = fString

 	for counter1 = 1 to TagCount

 		oTag   = CodeTags(counter1,1,1)
 		roTag1  = CodeTags(counter1,1,2)
		roTag2  = CodeTags(counter1,1,3)
 		cTag   = CodeTags(counter1,2,1)
 		rcTag1  = CodeTags(counter1,2,2)
		rcTag2  = CodeTags(counter1,2,3)
 		oTagPos = InStr(1, strTempString, oTag, 1)
 		cTagPos = InStr(1, strTempString, cTag, 1)

 		if (oTagpos > 0) and (cTagPos > 0) then
 		 	strArray = Split(strTempString, oTag, -1, 1)
 		 	for counter2 = 0 to Ubound(strArray)
 		 		if (Instr(1, strArray(counter2), cTag) > 0) then
 		 			strArray2 = split(strArray(counter2), cTag, -1, 1)
					strCodeText = trim(strArray2(0))						
					if (LCase(Left(strCodeText,2))="<a") then
						strArray3 = split(strCodeText, ">", -1, 1)						
						if (UBound(strArray3)>0) then
							strCodeText = Left(strArray3(1), Len(strArray3(1))-3)																					
							strArray3 = split(strCodeText, "?", -1, 1)													
							if (UBound(strArray3)>0) then																															
								strCodeText = strArray3(1)
								strArray3 = split(strCodeText, "&", -1, 1)
								for counter3 = 0 to UBound(strArray3)								
									strArray4 = split(strArray3(counter3), "=", -1, 1)
									if (UBound(strArray4)=1)AND(LCase(strArray4(0))="v") then																											
										strCodeText = strArray4(1)									
										exit for
									end if
								next
							end if
						end if							
					end if
 		 			strResultString = strResultString & roTag1 & strCodeText & rcTag1 & roTag2 & strCodeText & rcTag2 & strArray2(1)
 		 		else
 		 			strResultString = strResultString & strArray(counter2)
 		 		end if	
 		 	next  
			strTempString = strResultString
 			strResultString = ""
 		end if
	next
	ReplaceYouTubeTags = strTempString
end function
%>
____________________________________

At line 239 change:

if strAllowForumCode = "1" then
		fString = extratags(fString)
	end if
____________________________________

to
____________________________________

if strAllowForumCode = "1" then
		fString = extratags(fString)
		fString = ReplaceYouTubeTags(fString)
	end if
____________________________________

Now you can use the brand new forum code!

____________________________________


If you want, you can modify "pop_forum_code.asp", 
adding the following code before if (strIMGInPosts = "1"), at line 158.


Response.Write "<p><b>YouTube:</b> Place the letter 's' after the http in the video URL (example https://www).  Next, enclose the video URL with [youtube] and [/youtube] .  <i>Example:</i> Here is a video: <b>[youtube]</b>http://www.youtube.com/watch?v=gJmX1z1NY2c<b>[/youtube]</b></p>" & vbNewLine
____________________________________

If you want a YouTube button, copy "icon_editor_youtube.gif" in your image folder 
(if you have not an image folder, use the root folder of the forum).

____________________________________


Modify "inc_code.js" adding at the end:


function youtube() {
	var text = getText();
	if (helpstat){
		alert("YouTube tag inserts a video hosted by YouTube into the post, but you will need to add the letter 's' after the http in your link.\n\nExample: [youtube]https://www.youtube.com/watch?v=gJmX1z1NY2c[/youtube]");
	} else if (basic) {
		AddTxt="[youtube]" + text + "[/youtube]";
		AddText(AddTxt);
	} else {
		txt=prompt("YouTube video URL","");
		if(txt!=null) {
			AddTxt="[youtube]"+txt+"[/youtube]";
			AddText(AddTxt);
		}
	}
}
____________________________________

Modify "inc_iconfiles.asp" adding (where you want):


Const strIconEditorYouTube = "icon_editor_youtube.gif|46|22"
____________________________________

Modify "inc_post_buttons.asp" adding after line 66, just before 'if lcase(strIcons) = "1" and strShowSmiliesTable = "0"':


Response.Write "<a href=""Javascript:youtube();"" tabindex=""-1"">" & getCurrentIcon(strIconEditorYouTube,"Insert YouTube","align=""top""") & "</a>" & vbNewLine
____________________________________

Ciao!
Luca Panella
http://www.lucapanella.com

Sep 01 2007

Snitz Member "webewitch" shared this below to allow full screen on YouTube video:

I've changed the code a wee bit to the now standard size of 640x390 and added the fullscreen button:

CodeTags(1,1,1) = "[youtube]"
CodeTags(1,2,1) = "[/youtube]"
CodeTags(1,1,2) = "<object width=""640"" height=""390""><param name=""movie"" value=""http://www.youtube.com/v/"
CodeTags(1,2,2) = "&fs=1""></param><param name=""allowFullScreen"" value=""true""></param><param name=""wmode"" value=""transparent""></param>"
CodeTags(1,1,3) = "<embed src=""http://www.youtube.com/v/"
CodeTags(1,2,3) = "&fs=1"" type=""application/x-shockwave-flash""allowfullscreen=""true"" wmode=""transparent"" width=""640"" height=""390""></embed></object>"


One slight problem I have is that while most of the videos work on my iPhone a few don't . e.g. this one; 

[youtube]http://www.youtube.com/watch?v=o-WZU1X--IM[/youtube]