<% Option Explicit
Dim id
Dim ConnString, Conn, strSql, rsMod
Dim adoStream, objFSO, objFile
Dim strFilePath, strPhyPath, strFileName, strFileSize, dteModDate
Dim intErrCount

intErrCount = 0

id = Request.QueryString("file_id")

if id <> "" and IsNumeric(id) then
	ConnString = "driver={MySQL ODBC 3.51 Driver};server=*****;uid=*****;pwd=*****;database=*****" '## MySQL
	set Conn = Server.CreateObject("ADODB.Connection")
	
	Conn.Open ConnString
	
	'### Get the path to the file from database
	strSql = "SELECT FILE_PATH FROM MOD_NAME WHERE FILE_ID = " & CInt(id)
	set rsMod = Server.CreateObject("ADODB.Recordset")
	rsMod.open strSql, Conn
	
	'Check if file exists
	if rsMod.EOF or rsMod.BOF then
		ErrorMsg()
		intErrCount = 1
	else
		'Store relative and physical file path in variables
		strFilePath = rsMod("FILE_PATH")
		strPhyPath = Server.MapPath(strFilePath)
	end if
	
	rsMod.close
	set rsMod = nothing
	
	if intErrCount = 0 then
		'if there were no errors, we update the download count for this file,
		'and get the file to begin download
		dteModDate = year(Now()) & doublenum(Month(Now())) & doublenum(Day(Now()))
		
		'### Update database with new download count
		strSql = "UPDATE MOD_INFO SET DOWNLOADS = DOWNLOADS + 1, DOWNLOAD_DATE = '" & dteModDate & "' WHERE FILE_ID = " & CInt(id)
		Conn.Execute(strSql)
		
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		Set objFile = objFSO.GetFile(strPhyPath)
		Set adoStream = Server.CreateObject("ADODB.Stream")
		
		adoStream.Open
		adoStream.Type = 1
		adoStream.LoadFromFile strPhyPath
		
		strFileName = Mid(strFilePath, InStrRev(strFilePath, "/")+1) 'the file name
		strFileSize = objFile.Size 'file size
		
		Response.ContentType = "application/zip" 'type of file they will be downloading
		Response.AddHeader "Content-Disposition", "attachment;filename=" & strFileName & ""  'forces the save/open box
		Response.AddHeader "Content-Length", strFileSize 'optional: send file size to browser
		Response.BinaryWrite adoStream.Read
		Response.Flush
		
		adoStream.Close
		Set adoStream = nothing
		Set objFile = nothing
		Set objFSO = nothing
	end if
		
	Conn.Close
	set Conn = nothing

else
	'call error message when id is empty or is not a number
	ErrorMsg()
end if

function doublenum(Num)
	if Num > 9 then 
		doublenum = Num 
	else 
		doublenum = "0" & Num
	end if
end function
%>