quote:

---

Originally posted by PuppyF500

How can i add a collapse function to for example the table the birthday mod creates?

---

if strDBNTUserName <> "" then
        '### Read/write the cookies (take a look at the DoHideCategory sub on default.asp
        Call DoHideCategory("PMs") 
        '### Define the variable for the cookies and querystring
       	HideForumCat = strUniqueID & "HideCat" & "PMs" 
        '### The following code gets the info to be displayed in the PM table, so we only need it if the PMs are not hidden 
	If Request.Cookies(HideForumCat) <> "Y" Then
	      ' Get Private Message count for display on Default.asp
		if strDBType = "access" then
			strSqL = "SELECT count(M_TO) as [pmcount] "
		else
	        		strSqL = "SELECT count(M_TO) as pmcount "
    		end if
		strSql = strSql & " FROM " & strMemberTablePrefix & "MEMBERS , " & strTablePrefix & "PM "
		strSql = strSql & " WHERE " & strMemberTablePrefix & "MEMBERS.M_NAME = '" & strDBNTUserName & "'"
		strSql = strSql & " AND " & strMemberTablePrefix & "MEMBERS.MEMBER_ID = " & strTablePrefix & "PM.M_TO "
		strSql = strSql & " AND " & strTablePrefix & "PM.M_READ = 0 "
	
		Set rsPM = my_Conn.Execute(strSql)
		pmcount = rsPM("pmcount")
       	
		rsPM.close
		set rsPM = nothing
        End If
	Response.Write	"        <tr>" & vbNewLine
        '### Now we have to add the collapse/expand icons and links to the category cell
	If Request.Cookies(HideForumCat) = "Y" Then
	 	Response.Write	"          <td bgcolor=""" & strCategoryCellColor & """ colspan=""" & sGetColspan(7,6) & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strCategoryFontColor & """ size=""+1""><a href=""" & ScriptName & "?" & HideForumCat & "=N"">" & getCurrentIcon(strIconPlus,"Expand This Category","") & "</a> <b>Private Messages</b></font></td>" & vbNewLine
	Else
 		Response.Write	"          <td bgcolor=""" & strCategoryCellColor & """ colspan=""" & sGetColspan(7,6) & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strCategoryFontColor & """ size=""+1""><a href=""" & ScriptName & "?" & HideForumCat & "=Y"">" & getCurrentIcon(strIconMinus,"Collapse This Category","") & "</a> <b>Private Messages</b></font></td>" & vbNewLine
 	End If
	Response.Write	"        </tr>" & vbNewLine
        '### The following code is the one we want to hide if the collapse icon was clicked:
	If Request.Cookies(HideForumCat) <> "Y" Then
		Response.Write	"        <tr>" & vbNewLine & _
				"          <td align=""center"" bgcolor=""" & strForumCellColor & """ valign=""middle""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strCategoryFontColor & """>"
		if strDBNTUserName = "" then
			Response.Write	" "
		else
			if pmcount = 0 then
				Response.Write	" "
			end if
       	         if pmcount >= 1 then
				Response.Write	getCurrentIcon(strIconpmnewsm,"","align=""absmiddle""")
			end if
		end if
		Response.Write	"</font></td>" & vbNewLine & _
				"          <td valign=""top"" bgcolor=""" & strForumCellColor & """ colspan=""" & sGetColspan(6,5) & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strForumFontColor & """><span class=""spnMessageText""><a href=""pm_view.asp"">Inbox</a></span></font>" & vbNewLine
	       	if strDBNTUserName = "" then
			Response.Write	"<font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """ color=""" & strForumFontColor & """><br> - Log in to check your private messages.</font>" & vbNewLine
		else
			Response.Write	"<font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """ color=""" & strForumFontColor & """><br><b>"
			if strAuthType="nt" then
				Response.Write	strDBNTUserName & " (" & strDBNTUserName & ")</b>"
			else
				if strAuthType = "db" then
					Response.Write	strDBNTUserName & "</b>"
				end if
			end if
			Response.Write	" - You have "
			if pmcount >=1 then
				Response.Write	"<font color=""" & strActiveLinkColor & """><b>" & pmcount & "</b></font>"
			else
				Response.Write	pmcount
			end if
			Response.Write	" new private message"
			if pmcount >1 then
				Response.Write	"s"
			end if
			Response.Write	".</font></td>" & vbNewLine & _
					"        </tr>" & vbNewLine
		end if
	End If
end if