' Function fLangSP(s: string, paramlist)
' Used for sentences which are mixed with variables from code AND has singular-plural cases. Parameters are parsed and inserted
' into the sentence. The places of insertion are defined in the value of the string as %sN% where N
' (1,2,3...) indicates the variable. The singular/plural words are indicated by [%N]singular|plural[/%N] where N is the
' numeric parameter to be checked for using singular or plural case.
' INPUT
'	==== s: String of language variable name ==== changed for IIS4 compatibility
'	s: String (language variable)
'	paramlist: String, Separeted list of variable values. The format is : "param1|param2|..."
'				where | is used as separetor. ParamN is used to replace variable %sN%.
' EXAMPLE
'	==== response.write fLangSP("strLangDefault00060", intNoOfRecords & "|" & intMaxRecords) ==== changed for IIS4 compatibility
'	response.write fLangSP(strLangDefault00060, intNoOfRecords & "|" & intMaxRecords)
'
function fLangSP(s, paramlist)
DIM s1, s2, arrParam, sp, N, i, pos1, pos2, pos3, strErr
'	s=eval(s) ' commented out for IIS 4 compatibility, all related function calls changed
	s1 = s
	arrParam = split(paramlist, "|")
	N=ubound(arrParam)
	for i=0 to N
		s1=replace(s1,"%s" & i+1 & "%", arrParam(i))
		pos1 = 1
		strErr = ""
		Do While pos1 > 0
			pos1 = InStr(1, s1, "[%" & i+1 & "]", 0)
			if pos1 > 0 then ' starting tag found, so search for closing tag
				pos2 = InStr(pos1, s1, "[/%" & i+1 & "]", 0)
				if pos2 > 0 then ' closing tag found, so extract singular|plural string and search for "|" separator
					s2=mid(s1, pos1+4, (pos2-1)-(pos1+4)+1) ' get the content
					pos3 = InStr(1, s2, "|", 0)
					if pos3 > 0 then 'do the replacement
						if arrParam(i) = 1 then ' singular case
							s1 = left(s1, pos1-1) & left(s2,pos3-1) & mid(s1, pos2+5)
						else ' plural case
							s1 = left(s1, pos1-1) & mid(s2,pos3+1) & mid(s1, pos2+5)
						end if
					else ' error: no separator
						strErr = strErr & " Error: No Separator in " & mid(s1,pos1,pos2+4-pos1+1)
					end if
				else ' error: no closing tag
					strErr = strErr & " Error: No Closing Tag for " & mid(s1,pos1,4)
				end if
			end if
		loop
	next
	if blnLangDebug then
		fLangSP = "*" & s1
	else
		fLangSP = s1
	end if
end function

strLangTest = "There [%1]is|are[/%1] %s1% [%1]topic|topics[/%1] in %s2% [%2]forum|forums[/%2]."

response.write fLangSP(strLangTest, "2|1")

quote:

---

fixed...

---

What was it ?


Think Pink
==> Start Internationalization Here<

quote:

---

just edit the post and look where I inserted this: (it's in 2 places)

[b][/b]

---

quote:

---

Where should I put it?

---

quote:

---

When number ended with 1 (example: 1, 21, 51, etc) it must be writed as "ôîðóì" (in russian)
When number ended with 2 to 4 (example: 2, 23, 54, etc) it must be writed as "ôîðóìà"
When number ended with 5 to 10 and from 11 to 20 (example: 0, 5, 27, 60, etc) it must be writed as "ôîðóìîâ"

---

quote:

---

If I want to show the time since a user has logged in I would write "1 minute" but for any other amounts I wanted to show "x minutes" where x may assume any value <> 1.
Doesn't the funcion force you to have all the possible values listed, separated by '|'? If so (and it seems so) it is not as useful as it could be, right?

---

I think I understand this. The first version of the function given above is valid for languages which have "regular" singular/plurals, and those with no singular/plurals:

Singular : =1
Plural   : <> 1

It also deals with cases like in Turkish (below is the Turkish translation for "1 child is coming" and "10 children are coming")

Singular : 1 çocuk geliyor
Plural   : 10 çocuk geliyorlar

As you see, the word "çocuk=child" does not get the plural, because "10 çocuk" is considered as plural, and double plural is forbidden in Turkish. But the verb has "lar" at the end to make it plural.

So I can use the above function like this

strLangTest = "%s1% [%1]çocuk|çocuk[/%1] [%1]geliyor|geliyorlar[/%1]."

and call it like

fLangSP(strLangTest, intNoOfChildren)

Coming to your question... No it does not need multiple values in English and in most languages. You can use:

strLangTest = "%s1% [%1]minute|minutes[/%1]"

and call it like

fLangSP(strLangTest, intNoOfMinutes)

So the possible outputs are:

"1 minute"

and

"2 minutes" (you can have any number instead of "2" except "1" to get this)

While thinking I have these questions:

• how do you handle 0 (zero) => "there are 0 topics"


• how do you handle negative numbers (zero) => "there are -5 topics"


• how do you handle decimal numbers => "You are online for 3.57 minutes"

It does not handle cases like survivor told us above thou, i.e. different ranges for different words. I'm working on a new more "customizable" version to also handle these cases. I plan to work together with survivor to get it right.


Think Pink
==> Start Internationalization Here

Edited by - bozden on 22 May 2002 17:25:14<