Snitz Forums 2000
Snitz Forums 2000
Home | Profile | Register | Active Topics | Members | Search | FAQ
Username:
 Password:
Save Password
Forgot your Password?

 All Forums
 Snitz Forums 2000 MOD-Group
 MOD Add-On Forum (W/O Code)
 Add-on for Registration/Profile Area		  New Topic  Reply to Topic
 Printer Friendly
Author Previous Topic Topic Next Topic  

MaGraham
Senior Member

USA
1297 Posts
Posted - 10 September 2012 :  19:49:06  Show Profile  Reply with Quote


Since my entire website is private, I am always curious as to how someone finds us. Thus far, it's always been that a member has invited someone.

I had an idea and I was wondering if it would be much trouble to add something to the profile/registration area. I would like to add a question in that area and simply ask "How did you find us" or "Who referred you" or possibly both.

And since I have a drop menu for those who live in the United States to choose their state, I would love to have an option for those from other countries to list their provinces. The mod seem to only offer one or the other but not both.

And if it's just something really simple, I would also like to add a place for their username for their Facebook, Twitter. Pinterest and possibly their Google account as well.

If this all is something really simple and someone would like to jump on it really quick I am providing a copy of my register.asp and my pop_profile.asp in txt format.

If all of this is just too much to ask, I would be happy to simply have the question I mentioned added. :)




pop_profile.asp in txt format

register.asp in txt format
"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley

Carefree
Advanced Member

Philippines
4217 Posts
Posted - 11 September 2012 :  11:14:46  Show Profile  Reply with Quote
The first step will be fairly easy to add, but I cannot get to it before I return from this trip (early next week). Including all the provinces, etc., for every country in the world would be a MUCH larger modification, although smaller than the IPtoCountry mod. Not sure I'd want to tackle that one any more. Finally, adding options for Twitter, etc., would also be a small modification ... but where do you stop? Then someone will want the online dating sites, etc., etc., etc.
Go to Top of Page

MaGraham
Senior Member

USA
1297 Posts
Posted - 11 September 2012 :  13:59:11  Show Profile  Reply with Quote

I didn't word my post properly, Carefree. I'm sorry.

What I am requesting is a place for the members to type their province.

The online dating sites are much too personal, in my opinion, so I would never request a place for members to list that. :)


"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Go to Top of Page

Carefree
Advanced Member

Philippines
4217 Posts
Posted - 12 September 2012 :  03:22:00  Show Profile  Reply with Quote
A simple field would be easy for the province mod. Maybe I can do all three next week, I have a number of meetings to attend when I return but will take a look at them.
Go to Top of Page

MaGraham
Senior Member

USA
1297 Posts
Posted - 13 September 2012 :  10:02:55  Show Profile  Reply with Quote

Thank you, Carefree! You are such a dear! :)
"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Go to Top of Page

Carefree
Advanced Member

Philippines
4217 Posts
Posted - 30 October 2012 :  17:27:17  Show Profile  Reply with Quote
Sorry, forgot this one.

For part 1, not sure how you want to track/use the data, so didn't make a page for that.

  • Save the following as "dbs_referred.asp" and run it from admin console:

    
Registration Referral

[ALTER]
MEMBERS
ADD#M_REFERRED#VARCHAR (255)#NULL#
[END]

[ALTER]
MEMBERS_PENDING
ADD#M_REFERRED#VARCHAR (255)#NULL#
[END]

  • "register.asp"
    
Look for the following lines (appx 733-738):

			if strQuote = "1" then
				strSql = strSql & ", '" & ChkString(Request.Form("Quote"),"message") & "'"
			else
				strSql = strSql & ", ''"
			end if
			strSql = strSql & ", 1"

Change them to say:

			if strQuote = "1" then
				strSql = strSql & ", '" & ChkString(Request.Form("Quote"),"message") & "'"
			else
				strSql = strSql & ", ''"
			end if
			strSql = strSql & ", '" & ChkString(Request.Form("Referred"),"message") & "'"


Look for the following line (appx 599):

			strSql = strSql & ", M_QUOTE"

After it, insert this:

			strSql = strSql & ", M_REFERRED"


Look for the following line (appx 182):

			strSql = strSql & ", '" & chkString(rsKey("M_QUOTE"),"message") & "'"

After it, insert this:

			strSql = strSql & ", '" & chkString(rsKey("M_REFERRED"),"message") & "'"


Look for the following line (appx 142):

			strSql = strSql & ", M_QUOTE"

After it, insert this:

			strSql = strSql & ", M_REFERRED"


Look for the following line (appx 87):

			 ", M_BIO, M_HOBBIES, M_LNEWS, M_QUOTE, M_SHA256" & _

Change it to say:

			 ", M_BIO, M_HOBBIES, M_LNEWS, M_QUOTE, M_REFERRED, M_SHA256" & _

  • "inc_profile.asp"
    
Look for the following lines (appx 744-750):

	Response.Write	"                  </table>" & vbNewLine & _
			"                </td>" & vbNewLine & _
			"              </tr>" & vbNewLine & _
			"            </table>" & vbNewLine & _
			"          </td>" & vbNewLine & _
			"        </tr>" & vbNewLine & _
			"      </table>" & vbNewLine

Above those, insert these:

	If strMode = "Register" then
		Response.Write	"                    <tr>" & vbNewLine & _
			"                      <td bgColor=""" & strPopUpTableColor & """ align=""right"" valign=""middle"" nowrap width=""10%""><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>How did you find us? </font></b></td>" & vbNewLine & _
			"                      <td bgColor=""" & strPopUpTableColor & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """><input name=""Referred"" size=""25"" maxLength=""255"" value=""" & Request.Form("Referred") & """>" & vbNewLine & _
			"											 </font></td></tr>" & vbNewLine
	End If


Look for the following lines (appx 266-275):

			if strQuote = "1" then
				Response.Write "                    <tr>" & vbNewLine
				if strReqQuote = "1" then
					Response.Write "                      <td bgcolor=""" & strPopUpTableColor & """ valign=""top"" align=""right"" nowrap width=""10%""><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """><font color=""" & strHiLiteFontColor & """>*</font> Favorite Quote: </font></b></td>" & vbNewLine
				else
					Response.Write "                      <td bgcolor=""" & strPopUpTableColor & """ valign=""top"" align=""right"" nowrap width=""10%""><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>Favorite Quote: </font></b></td>" & vbNewLine
				end if
				Response.Write "                      <td bgColor=""" & strPopUpTableColor & """ valign=""top""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """><textarea name=""Quote"" cols=""30"" rows=""4"">" & Trim(cleancode(strMyQuote)) & "</textarea></font></td>" & vbNewLine & _
						"                    </tr>" & vbNewLine
			end if

[navyAfter those, insert these:

			if strReferral = "1" then
				Response.Write "                    <tr>" & vbNewLine
				if strReqReferral= "1" then
					Response.Write "                      <td bgcolor=""" & strPopUpTableColor & """ valign=""top"" align=""right"" nowrap width=""10%""><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """><font color=""" & strHiLiteFontColor & """>*</font> Referral: </font></b></td>" & vbNewLine
				else
					Response.Write "                      <td bgcolor=""" & strPopUpTableColor & """ valign=""top"" align=""right"" nowrap width=""10%""><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>Where did you hear about us? </font></b></td>" & vbNewLine
				end if
				Response.Write "                      <td bgColor=""" & strPopUpTableColor & """ valign=""top""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """><input type=""text"" size=""25"" maxLength=""255"" name=""Referred"" value=""" & Trim(cleancode(rs("M_REFERRED"))) & """></font></td>" & vbNewLine & _
						"                    </tr>" & vbNewLine
			end if


    • To enable making it a required field:

  • "admin_config_members.asp"
    
Search for the following lines (appx 425-436):

Response.Write         "              <tr valign=""top"">" & vbNewLine & _
		"                <td bgColor=""" & strPopUpTableColor & """ align=""right""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """><b>Enabled:</b> </font></td>" & vbNewLine & _
		"                <td bgColor=""" & strPopUpTableColor & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>" & vbNewLine & _
		"                On: <input type=""radio"" class=""radio"" name=""strQuote"" value=""1""" & chkRadio(strQuote,0,false) & "> " & vbNewLine & _
		"                Off: <input type=""radio"" class=""radio"" name=""strQuote"" value=""0""" & chkRadio(strQuote,0,true) & ">" & vbNewLine & _
		"                <a href=""JavaScript:openWindow3('pop_config_help.asp?mode=members#Quote')"">" & getCurrentIcon(strIconSmileQuestion,"","") & "</a></td>" & vbNewLine & _
		"              </tr>" & vbNewLine
Response.Write         "                <td bgColor=""" & strPopUpTableColor & """ align=""right""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """><b>Required:</b> </font></td>" & vbNewLine & _
		"                <td bgColor=""" & strPopUpTableColor & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>" & vbNewLine & _
		"                On: <input type=""radio"" class=""radio"" name=""strReqQuote"" value=""1""" & chkRadio(strReqQuote,0,false) & "> " & vbNewLine & _
		"                Off: <input type=""radio"" class=""radio"" name=""strReqQuote"" value=""0""" & chkRadio(strReqQuote,0,true) & ">" & vbNewLine & _
		"              </tr>" & vbNewLine

After those, insert these:
Response.Write         "              <tr valign=""top"">" & vbNewLine & _
		"              <td bgColor=""" & strCategoryCellColor & """ colspan=""2"" align=""center""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strCategoryFontColor & """><b>Referral</b></font></td>" & vbNewLine & _
		"              </tr>" & vbNewLine
Response.Write         "              <tr valign=""top"">" & vbNewLine & _
		"                <td bgColor=""" & strPopUpTableColor & """ align=""right""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """><b>Enabled:</b> </font></td>" & vbNewLine & _
		"                <td bgColor=""" & strPopUpTableColor & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>" & vbNewLine & _
		"                On: <input type=""radio"" class=""radio"" name=""strReferral"" value=""1""" & chkRadio(strReferral,0,false) & "> " & vbNewLine & _
		"                Off: <input type=""radio"" class=""radio"" name=""strReferral"" value=""0""" & chkRadio(strReferral,0,true) & ">" & vbNewLine & _
		"                <a href=""JavaScript:openWindow3('pop_config_help.asp?mode=members#Referral')"">" & getCurrentIcon(strIconSmileQuestion,"","") & "</a></td>" & vbNewLine & _
		"              </tr>" & vbNewLine
Response.Write         "                <td bgColor=""" & strPopUpTableColor & """ align=""right""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """><b>Required:</b> </font></td>" & vbNewLine & _
		"                <td bgColor=""" & strPopUpTableColor & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>" & vbNewLine & _
		"                On: <input type=""radio"" class=""radio"" name=""strReqReferral"" value=""1""" & chkRadio(strReqReferral,0,false) & "> " & vbNewLine & _
		"                Off: <input type=""radio"" class=""radio"" name=""strReqReferral"" value=""0""" & chkRadio(strReqReferral,0,true) & ">" & vbNewLine & _
		"              </tr>" & vbNewLine


  • "config.asp"
    
Search for the following line (appx 372):

strReqQuote = Application(strCookieURL & "STRREQQUOTE")

After that, insert this:

strReqReferral = Application(strCookieURL & "STRREQREFERRAL")


Search for the following line (appx 345):

strQuote = Application(strCookieURL & "STRQUOTE")


After that, insert this:

strReferral = Application(strCookieURL & "STRREFERRAL")

Search for the following line (appx 142):

Dim strReqHobbies, strReqLNews, strReqQuote, strReqMarStatus, strReqFavLinks

Change it to say:

Dim strReqHobbies, strReqLNews, strReqQuote, strReqReferral, strReqMarStatus, strReqFavLinks

Search for the following line (appx 137):

Dim strHobbies, strLNews, strQuote, strMarStatus, strFavLinks

Change it to say:

Dim strHobbies, strLNews, strQuote, strReferral, strMarStatus, strFavLinks


  • "register.asp"
    
Look for the following lines (appx 315-320):

		if strQuote = "1" and strReqQuote = "1" then
			if trim(Request.Form("Quote")) = "" then
				Err_Msg = Err_Msg & "<li>You Must Provide A Quote</li>"
			end if
		end if
After them, insert these:

		if strReferral = "1" and strReqReferral = "1" then
			if trim(Request.Form("Referred")) = "" then
				Err_Msg = Err_Msg & "<li>You Must Provide A Reference</li>"
			end if
		end if


  • "pop_profile.asp"
    
Look for the following lines (appx 1729-1731):

					if strQuote = "1" then
						strSql = strSql & ", M_QUOTE = '" & chkString(Request.Form("Quote"),"message") & "'" 
					end if

After those, insert these:

					if strReferral = "1" then
						strSql = strSql & ", M_REFERRED = '" & chkString(Request.Form("Referred"),"message") & "'" 
					end if

Look for the following lines (appx 1376-1378):

			if strQuote = "1" then
				strSql = strSql & ",	M_QUOTE = '" & ChkString(Request.Form("Quote"),"message") & "'"
			end if

After those, insert these:

			if strReferral = "1" then
				strSql = strSql & ",	M_Referred = '" & ChkString(Request.Form("Referred"),"message") & "'"
			end if

Look for the following lines (appx 1132-1136):

		if strQuote = "1" and strReqQuote = "1" then
			if trim(Request.Form("Quote")) = "" then
				Err_Msg = Err_Msg & "<li>You Must Provide A Quote</li>"
			end if
		end if

After those, insert these:

		if strReferral = "1" and strReqReferral = "1" then
			if trim(Request.Form("Referred")) = "" then
				Err_Msg = Err_Msg & "<li>You Must Provide A Reference</li>"
			end if
		end if

Look for the following line (appx 969):

				strsql = strsql & ", " & strMemberTablePrefix & "MEMBERS.M_QUOTE"

After it, insert this:

				strsql = strsql & ", " & strMemberTablePrefix & "MEMBERS.M_REFERRED"

Look for the following line (appx 837):

		strsql = strsql & ", " & strMemberTablePrefix & "MEMBERS.M_QUOTE"

After it, insert this:

		strsql = strsql & ", " & strMemberTablePrefix & "MEMBERS.M_REFERRED"

Look for the following lines (appx 669-677):

				if strQuote = "1" then  
					Response.Write	"                    <tr>" & vbNewLine & _
							"                      <td bgcolor=""" & strPopUpTableColor & """ valign=""top"" align=""right"" nowrap width=""10%""><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>Favorite Quote: </font></b></td>" & vbNewLine & _
							"                      <td bgColor=""" & strPopUpTableColor & """ valign=""top""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>"
					if IsNull(strMyQuote) or Trim(strMyQuote) = "" then Response.Write("-") else Response.Write(formatStr(strMyQuote))
					Response.Write	"</font></td>" & vbNewLine & _
							"                    </tr>" & vbNewLine
				end if
			end if

After those, insert these:

			if strReferral = "1" then  
				Response.Write	"                    <tr>" & vbNewLine & _
						"                      <td bgcolor=""" & strPopUpTableColor & """ valign=""top"" align=""right"" nowrap width=""10%""><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>Where did you hear about us? </font></b></td>" & vbNewLine & _
						"                      <td bgColor=""" & strPopUpTableColor & """ valign=""top""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>"
				if IsNull(strReferral) or Trim(strReferral) = "" then Response.Write("-") else Response.Write(formatStr(strReferral))
				Response.Write	"</font></td>" & vbNewLine & _
						"                    </tr>" & vbNewLine
			end if

Look for the following line (appx 640):

			if IsNull(strMyQuote) or trim(strMyQuote) = "" then strQuote = 0

After it, insert this:

			if IsNull(strReferral) or trim(strReferral) = "" then strReferral = 0

Look for the following line (appx 227):

			strMyQuote = rs("M_QUOTE")

After it, insert this:

			strReferral = rs("M_REFERRED")

Look for the following line (appx 196):

		strsql = strsql & ", " & strMemberTablePrefix & "MEMBERS.M_QUOTE"

After it, insert this:

		strsql = strsql & ", " & strMemberTablePrefix & "MEMBERS.M_REFERRED"


    • For an admin statistics page:

  • "admin_home.asp"

    
Look for the following line (appx 145):

		"                <LI><span class=""spnMessageText""><a href=""admin_member_search.asp"">Member Search</a></span></LI>" & vbNewLine & _

Above that, insert this:

		"                <LI><span class=""spnMessageText""><a href=""admin_referrals.asp"">Members: Referrals</a></span></LI>" & vbNewLine & _


  • "admin_referrals.asp"

    Note: Sorting by quantity doesn't work yet, have to figure out how to work around the select distinct.

    
<%
'###############################################################################
'##
'##	              Snitz Forums 2000 v3.4.07
'##
'###############################################################################
'##
'## Copyright © 2000-09 Michael Anderson, Pierre Gorissen,
'##	          Huw Reddick and Richard Kinser
'##
'## This program is free. You can redistribute and/or modify it under the
'## terms of the GNU General Public License as published by the Free Software
'## Foundation; either version 2 or (at your option) any later version.
'##
'## All copyright notices regarding Snitz Forums 2000 must remain intact in
'## the scripts and in the HTML output.  The "powered by" text/logo with a
'## link back to http://forum.snitz.com in the footer of the pages MUST
'## remain visible when the pages are viewed on the internet or intranet.
'##
'## This program is distributed in the hope that it will be useful but
'## WITHOUT ANY WARRANTY; without even an implied warranty of MERCHANTABILITY
'## or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
'## for more details.
'##
'## You should have received a copy of the GNU General Public License along
'## with this program; If not, write to:
'##
'##	          Free Software Foundation, Inc.
'##	          59 Temple Place, Suite 330
'##	          Boston, MA 02111-1307
'##
'## Support can be obtained from our support forums at:
'##
'##	            http://forum.snitz.com
'##
'## Correspondence and marketing questions can be sent to:
'##
'##	             manderson@snitz.com
'##
'###############################################################################
'##
'## admin_referrals.asp
'##
'###############################################################################
%>
<!--#INCLUDE FILE="config.asp"-->
<!--#INCLUDE FILE="inc_sha256.asp"-->
<!--#INCLUDE FILE="inc_header.asp" -->
<!--#INCLUDE FILE="inc_func_admin.asp" -->
<!--#INCLUDE FILE="inc_func_member.asp" -->
<%
If Session(strCookieURL & "Approval") <> "15916941253" Then 
	scriptname = split(request.servervariables("SCRIPT_NAME"),"/")
	Response.Redirect "admin_login.asp?target=" & scriptname(ubound(scriptname))
end if
Response.Write	"<table border=""0"" width=""100%"">" & vbNewLine & _
	"	<tr>" & vbNewLine & _
	"		<td width=""33%"" align=""left"" nowrap><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>" & vbNewLine & _
	"			" & getCurrentIcon(strIconFolderOpen,"","") & " <a href=""default.asp"">All Forums</a><br />" & vbNewLine & _
	"			" & getCurrentIcon(strIconBar,"","") & getCurrentIcon(strIconFolderOpen,"","") & " <a href=""admin_home.asp"">Admin Section</a><br />" & vbNewLine & _
	"			" & getCurrentIcon(strIconBlank,"","") & getCurrentIcon(strIconBar,"","") & getCurrentIcon(strIconFolderOpenTopic,"","") & " Member Referrals<br /></font>" & vbNewLine & _
	"		</td>" & vbNewLine & _
	"	</tr>" & vbNewLine & _
	"</table><br />" & vbNewLine & _
  "<table border=""0"" width=""50%"" cellspacing=""0"" cellpadding=""0"" align=""center"">" & vbNewLine & _
	"	<tr>" & vbNewLine & _
	"		<td bgcolor=""" & strPopUpBorderColor & """>" & vbNewLine & _
	"			<table border=""0"" width=""100%"" cellspacing=""1"" cellpadding=""4"">" & vbNewLine & _
	"				<tr valign=""middle"">" & vbNewLine & _
	"					<td align=""center"" colspan=""2"" width=""100%"" bgcolor=""" & strCategoryCellColor & """>" & vbNewLine & _
	"						<font face=""" & strDefaultFontFace & """ size=""" & strHeaderFontSize+1 & """ color=""" & strCategoryFontColor & """><b>Member Referrals</b>" & vbNewLine & _
	"						</font>" & vbNewLine & _
	"					</td>" & vbNewLine & _
	"				</tr>" & vbNewLine & _
	"				<tr valign=""middle"">" & vbNewLine & _
	"					<td align=""left"" bgcolor=""" & strHeadCellColor & """><a href=""admin_referrals.asp?sort="
If Request.QueryString("sort") = "source asc" Then Response.Write("source desc") Else Response.Write("source asc")
Response.Write	"""" & dWStatus("Sort by Source") & "><acronym style=""border:none; text-decoration:none"" title=""Sort by Source""><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strHeadFontColor & """><b>Source</b></font></b></acronym></a></td>" & vbNewLine & _
	"					<td align=""center"" bgcolor=""" & strHeadCellColor & """><a href=""admin_referrals.asp?sort="
If Request.QueryString("sort") = "qty asc" Then Response.Write("qty desc") Else Response.Write("qty asc")
Response.Write	"""" & dWStatus("Sort by Quantity") & "><acronym style=""border:none; text-decoration:none"" title=""Sort by Quantity""><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strHeadFontColor & """><b>Quantity</b></font></b></acronym></a></td>" & vbNewLine & _
	"				</tr>" & vbNewLine
strSort="":strCnt=""
If Request.QueryString("sort")>"" Then 
	strSorted=Request.QueryString("sort")
	If strSorted = "source asc" Then strSort="ORDER BY M_REFERRED ASC"
	If strSorted = "source desc" Then strSort="ORDER BY M_REFERRED DESC"
	If strSorted = "qty asc" Then strCnt="QTY ASC"
	If strSorted = "qty desc" Then strCnt="QTY DESC"
End If
strSql="SELECT DISTINCT(M_REFERRED) FROM " & strMemberTablePrefix & "MEMBERS WHERE M_REFERRED>''" & strSort
Set rsDis=my_Conn.Execute(strSql)
If not rsDis.EOF Then
	rsDis.MoveFirst
	intI=0
	Do while not rsDis.EOF
		strCnt="SELECT COUNT(M_REFERRED) AS CNT FROM " & strMemberTablePrefix & "MEMBERS WHERE M_REFERRED='" & rsDis("M_REFERRED") & "'"
		Set rsCnt=my_Conn.Execute(strCnt)
		If not rsCnt.EOF Then
			intCnt=rsCnt("CNT")
			rsCnt.Close
		End If
		Set rsCnt=Nothing
		If intI=0 Then CColor=strForumFirstCellColor Else CColor=strForumCellColor
		Response.Write	"				<tr valign=""middle"">" & vbNewLine & _
			"					<td align=""left"" width=""100%"" bgcolor=""" & CColor & """>" & vbNewLine & _
			"						<font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strForumFontColor & """>" & rsDis("M_REFERRED") & vbNewLine & _
			"						</font>" & vbNewLine & _
			"					</td>" & vbNewLine & _
			"					<td align=""center"" width=""100%"" bgcolor=""" & CColor & """>" & vbNewLine & _
			"						<font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strForumFontColor & """>" & intCnt & vbNewLine & _
			"						</font>" & vbNewLine & _
			"					</td>" & vbNewLine & _
			"				</tr>" & vbNewLine
		intI=1-intI
		rsDis.MoveNext
	Loop
	rsDis.Close
End If
Set rsDis=Nothing
Response.Write	"			</table>" & vbNewLine & _
	"		</td>" & vbNewLine & _
	"	</tr>" & vbNewLine & _
	"</table>" & vbNewLine
WriteFooter
%>


    • To add to EMail notification (if using the "Email Notification for User Registration Addon's" MOd):

  • "register.asp"

    
Search for this line, added by the mod:

strMessage = Request.Form("Name") & " (" & Request.Form("Email") & ") has registered at " & strForumURL 

After it, insert this:

strMessage = strMessage & vbNewline & vbNewline & "Referral source: " & strReferral
Edited by - Carefree on 14 November 2012 22:02:59
Go to Top of Page

MaGraham
Senior Member

USA
1297 Posts
Posted - 14 November 2012 :  01:48:54  Show Profile  Reply with Quote


I've been out of town for almost two months but I'm home now. I am off to try this.


"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Go to Top of Page

MaGraham
Senior Member

USA
1297 Posts
Posted - 14 November 2012 :  14:47:23  Show Profile  Reply with Quote

Working on the "To enable making it a required field" part now.

This is going to be wonderful!


"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Go to Top of Page

MaGraham
Senior Member

USA
1297 Posts
Posted - 16 November 2012 :  17:09:53  Show Profile  Reply with Quote


It looks good, Carefree! :)

There are two things I need to ask about.

1. There's not a red asterisk beside the "How did you find us" field when a member registers.
2. I need to be able to see what they type in that field either in my registration notification email I receive when someone registers or possibly in the area where you approve a pending member or just anywhere really.
"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Go to Top of Page
  Previous Topic Topic Next Topic  
 New Topic  Reply to Topic
 Printer Friendly
Jump To:
Snitz Forums 2000 © 2000-2021 Snitz™ Communications Go To Top Of Page
This page was generated in 0.68 seconds. Powered By: Snitz Forums 2000 Version 3.4.07