Snitz Forums 2000 - Showing counts on non forum pages

quote:
Perfect examples of why Snitz forums has failed to be a leader in forums apps. Amazing comments from a person that we have paid hundreds of dollars to in the past for help with our forums. And you say I am unappreciative!?

Well, you may have paid someone for help on a particular issue or even to set up a board, I don't know. I know that I didn't get paid "hundreds of dollars" for my thousands of messages trying to help people. I also know that it is customary to at least read a message (before discarding it) when someone tries to help you.

For what you wanted done, there MIGHT be an easier way but I don't see it.

Using the code I wrote is simple. Put lines 5-17 at the top of your page, before you need the information. Make sure to enclose them like this:


		<!--#INCLUDE VIRTUAL="itw/config.asp"-->
		<!--#INCLUDE VIRTUAL="itw/inc_func_common.asp"-->
		<%
		dim intMembers, intTopics, intForumID
		set my_Conn = Server.CreateObject("ADODB.Connection")
		my_Conn.Open(strConnString)
		strSql = "SELECT COUNT(MEMBER_ID) AS CNT FROM " & strMemberTablePrefix & "MEMBERS WHERE M_STATUS=1"
		set rsCount = my_Conn.Execute(strSql)
		if not rsCount.EOF then
			intMembers=rsCount("CNT")
			rsCount.Close
		end if
		set rsCount = Nothing
		%>

Note: If you're not going to use the member count anywhere, you can reduce the initial code a bit, like this:


		<!--#INCLUDE VIRTUAL="itw/config.asp"-->
		<!--#INCLUDE VIRTUAL="itw/inc_func_common.asp"-->
		<%
		dim intTopics, intForumID
		set my_Conn = Server.CreateObject("ADODB.Connection")
		my_Conn.Open(strConnString)
		%>

Then put the body of your page. Whereever you'd like the output of message counts, you'd use this (changing the forum numbers in red to the ones you wish displayed), adding lines in that pattern to display additional forums:


		<%		
		intForumID=1
		Call TopicsInForum(intForumID)
		intForumID=2
		Call TopicsInForum(intForumID)
		%>

Finally, at the bottom of the body segment of your web page (just above the closing < /body > tag, include the rest of the code I provided, like this:


		<%
		my_Conn.Close
		set my_Conn = Nothing

		Sub TopicsInForum(intForumID)
			'	##	Total Topics in a Particular Forum
			intForumTopics = 0
			strSql = "SELECT F_SUBJECT FROM " & strTablePrefix & "FORUM WHERE FORUM_ID=" & intForumID
			set rsTitle = my_Conn.Execute(strSql)
			if not rsTitle.EOF then
				strForumTitle=rsTitle("F_SUBJECT")
				rsTitle.Close
			end if
			set rsTitle=Nothing
			strSql = "SELECT COUNT(TOPIC_ID) AS CNT FROM " & strTablePrefix & "TOPICS WHERE T_STATUS=1 AND FORUM_ID=" & intForumID
			set rsCount = my_Conn.Execute(strSql)
			if not rsCount.EOF then
				intForumTopics=rsCount("CNT")
				rsCount.Close
			end if
			set rsCount = Nothing
			Response.Write	"Our """ & strForumTitle & """ forum currently has " & intForumTopics & " topics.<br>"
		End Sub
		%>

That's all there is to it. Unless you provide your page to me with a list of the forum IDs for me to do it for you, that's about as easy as it gets.