quote:

---

Originally posted by weeweeslap

hmm I logge din and made some sample posts and see the results, neither worked and I didn't do any tricks!

---

quote:

---

1. In the function FormatStr(), move this line "fString = ChkKeys(fString)" to here

function FormatStr(fString)
	on Error resume next
        fString = ChkKeys(fString)

---

quote:

---

I noticed that it changes the capitalization to whatever capitalization you have set in the XML file.

---

"#autokeywords{color:#333399;font-weight:normal;text-decoration:none;border-bottom:1px dashed;}" & vbNewLine & _
"#autokeywords:hover{color:red;font-weight:normal;text-decoration:none;border-bottom:1px dashed;}" & vbNewLine & _

quote:

---

Originally posted by leatherlips
The only thing left IMO is to maintain the case of the letters if possible.

---

quote:

---

Originally posted by leatherlips

Each time you upate your xml file or even change the target of the keyword links in the inc_func_common.asp file you must first uncomment the lines you mentioned, save the file and then uncomment the lines and then save again:

'if trim(Application(strCookieURL & "STRKEYWORDS")) = "" or trim(Application(strCookieURL & "STRKEYREPLACE")) = "" then
	LoadKeywordApps
'end if

---

1. Comment the two lines.


2. Save the file.


3. Make your changes.


4. Test the changes.


5. Un-comment the two lines.


6. Save the file again.

quote:

---

Originally posted by Carefree

I have the same issue with first/last occasionally not following set behaviour. Not sure what's causing it. I'm going to experiment & see if I can fix it, though.

---

quote:

---

Originally posted by cripto9t

Maybe there's just not enough room.

Leatherlips, for the bottom border try setting the line-height up.
I added a border to mine and like yours some worked and some didn't,
especially when they were on consecutive lines. Mine started working at 18px.

line-height:18px;

---

Function ChkKeys(fString)
    dim strFiles,iCnt,strKeys,strReplace,strClose,keywords,keyreplace,objRegex

    if ShowKeyWords = False then
        ChkKeys = fString
        Exit Function
    end if

    if trim(Application(strCookieURL & "STRKEYWORDS")) = "" or trim(Application(strCookieURL & "STRKEYREPLACE")) = "" then
	LoadKeywordApps
    end if

    strKeys = Application(strCookieURL & "STRKEYWORDS")
    strReplace = Application(strCookieURL & "STRKEYREPLACE")
    strClose = "</a>"
    if fString = "" or IsNull(fString) then fString = " "
    keywords = split(strKeys, ",")
    keyreplace = split(strReplace, ",")

    set objRegex = new RegExp
    objRegex.ignorecase = true
    objRegex.global = true
    for i = 0 to Ubound(keywords)
        strPattern = "^(" & keywords(i) & ")(\s)"
        strReplace = keyreplace(i) & "$1" & strClose & "$2"
        objRegex.pattern= strPattern
        fString = objRegex.replace(fString,strReplace)

        strPattern = "(" & keywords(i) & ")$"
        strReplace = keyreplace(i) & "$1" & strClose
        objRegex.pattern= strPattern
        fString = objRegex.replace(fString,strReplace)

        strPattern = "(""|'|\(|\[|{)(" & keywords(i) & ")(}|\]|\)|'|"")"
        strReplace = "$1" & keyreplace(i) & "$2" & strClose & "$3"
        objRegex.pattern= strPattern
        fString = objRegex.replace(fString,strReplace)

        strPattern = "(\s)(" & keywords(i) & ")(\s|\.|,|;|'|\?|!|\)|\]|}|"")"
        strReplace = "$1" & keyreplace(i) & "$2" & strClose & "$3"
        objRegex.pattern= strPattern
        fString = objRegex.replace(fString,strReplace)
    next

    ChkKeys = fString
End Function

Sub LoadKeywordApps()
    dim strPath,xmlDoc,strErr,xmlKeyList,NumOfKeys,strKeys,strReplace,iKey
    
    strPath = "C:\Inetpub\wwwroot\pool\key_db.xml"
    set xmlDoc=CreateObject("Microsoft.XMLDOM")
    xmlDoc.async="false"
    xmlDOc.setProperty "ServerHTTPRequest", true
    xmlDoc.load(strPath)

    if xmlDoc.parseError.errorCode <> 0 Then
        strErr = "<div><b>" & vbNewLine & _
                 "<ul>" & vbNewLine & _
                 "<li>ERROR!</li>" & vbNewLine & _
                 "<li>XML File " & strFileName & " - Failed to validate.</li>" & vbNewLine & _
                 "<li>" & xmlDoc.parseError.reason & "</li>" & vbNewLine & _
                 "<li>Error code: " & xmlDoc.parseError.errorCode & "</li>" & vbNewLine & _
                 "<li>Line: " & xmlDoc.parseError.line & "</li>" & vbNewLine & _
                 "<li>Character: " & xmlDoc.parseError.linepos & "</li>" & vbNewLine & _
                 "<li>Source: " & Chr(34) & xmlDoc.parseError.srcText & Chr(34) & "</li>" & vbNewLine & _
                 "<li>" & Now & "</li>" & vbNewLine & _
                 "</ul>" & vbNewLine & _
                 "</b></div>" & vbNewLine 

        Response.Write strErr
        Response.End
    end if

    set xmlKeyList = xmlDoc.getElementsByTagName("key")

    NumOfKeys = ((xmlKeyList.length) - 1)   '0 based

    strKeys = ""
    strReplace = ""

    for iKey = 0 to cLng(NumOfKeys)
        if strKeys = "" then
            strKeys = xmlKeyList.item(iKey).childNodes(0).text
            strReplace = "<a id=""keywords"" href=""" & xmlKeyList.item(iKey).childNodes(1).text & """ target=""blank"">"
        else
            strKeys = strKeys & "," & xmlKeyList.item(iKey).childNodes(0).text
            strReplace = strReplace & ", <a id=""keywords"" href=""" & xmlKeyList.item(iKey).childNodes(1).text & """ target=""blank"">"
        end if
    next

    set xmlKeyList = nothing
    set xmlDoc = nothing

    Application.Lock
    Application(strCookieURL & "STRKEYWORDS") = strKeys
    Application(strCookieURL & "STRKEYREPLACE") = strReplace
    Application.UnLock
End Sub