Would it be possible for the active.asp to have the "Collapse This Category" feature?

In my opinion, that would make is so much better than Facebook's Activity Feed! Just sayin'!

Here's my active.asp if someone can help. I can't seem to be able to figure it out.

<%
'###############################################################################
'##
'##                Snitz Forums 2000 v3.4.07
'##
'###############################################################################
'##
'## Copyright © 2000-09 Michael Anderson, Pierre Gorissen,
'##            Huw Reddick and Richard Kinser
'##
'## This program is free. You can redistribute and/or modify it under the
'## terms of the GNU General Public License as published by the Free Software
'## Foundation; either version 2 or (at your option) any later version.
'##
'## All copyright notices regarding Snitz Forums 2000 must remain intact in
'## the scripts and in the HTML output.  The "powered by" text/logo with a
'## link back to http://forum.snitz.com in the footer of the pages MUST
'## remain visible when the pages are viewed on the internet or intranet.
'##
'## This program is distributed in the hope that it will be useful but
'## WITHOUT ANY WARRANTY; without even an implied warranty of MERCHANTABILITY
'## or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
'## for more details.
'##
'## You should have received a copy of the GNU General Public License along
'## with this program; if not, write to:
'##
'##            Free Software Foundation, Inc.
'##            59 Temple Place, Suite 330
'##            Boston, MA 02111-1307
'##
'## Support can be obtained from our support forums at:
'##
'##              http://forum.snitz.com
'##
'## Correspondence and marketing questions can be sent to:
'##
'##               manderson@snitz.com
'##
'###############################################################################
%>
<!--#INCLUDE FILE="config.asp"-->
<%
nRefreshTime = Request.Cookies(strCookieURL & "Reload")
If Request.Form("cookie") = "1" Then
   If strSetCookieToForum = 1 Then
      Response.Cookies(strCookieURL & "Reload").Path = strCookieURL
   End If
   Response.Cookies(strCookieURL & "Reload") = Request.Form("RefreshTime")
   Response.Cookies(strCookieURL & "Reload").Expires = strForumTimeAdjust + 365
   nRefreshTime = Request.Form("RefreshTime")
End If
If nRefreshTime = "" Then
   nRefreshTime = 10
End If
ActiveSince = Request.Cookies(strCookieURL & "ActiveSince")
If Request.Form("cookie") = "2" Then
   ActiveSince = Request.Form("ShowSinceDateTime")
   If strSetCookieToForum = 1 Then
      Response.Cookies(strCookieURL & "ActiveSince").Path = strCookieURL
   End If
   Response.Cookies(strCookieURL & "ActiveSince") = ActiveSince
End If
Dim ModerateAllowed
Dim HasHigherSub
Dim HeldFound, UnApprovedFound, UnModeratedPosts, UnModeratedFPosts
Dim canView
HasHigherSub = false
%>
<!--#INCLUDE FILE="inc_sha256.asp" -->
<!--#INCLUDE FILE="inc_header.asp" -->
<!--#INCLUDE FILE="inc_func_secure.asp" -->
<!--#INCLUDE FILE="inc_moderation.asp" -->
<!--#INCLUDE FILE="inc_subscription.asp" -->
<!--#INCLUDE FILE="inc_birthdays.asp" -->
<%
Select Case ActiveSince
   Case "LastVisit"
      lastDate = ""
   Case "LastFifteen"
      lastDate = DateToStr(DateAdd("n",-15,strForumTimeAdjust))
   Case "LastThirty"
      lastDate = DateToStr(DateAdd("n",-30,strForumTimeAdjust))
   Case "LastFortyFive"
      lastDate = DateToStr(DateAdd("n",-45,strForumTimeAdjust))
   Case "LastHour"
      lastDate = DateToStr(DateAdd("h",-1,strForumTimeAdjust))
   Case "Last2Hours"
      lastDate = DateToStr(DateAdd("h",-2,strForumTimeAdjust))
   Case "Last6Hours"
      lastDate = DateToStr(DateAdd("h",-6,strForumTimeAdjust))
   Case "Last12Hours"
      lastDate = DateToStr(DateAdd("h",-12,strForumTimeAdjust))
   Case "LastDay"
      lastDate = DateToStr(DateAdd("d",-1,strForumTimeAdjust))
   Case "Last2Days"
      lastDate = DateToStr(DateAdd("d",-2,strForumTimeAdjust))
   Case "LastWeek"
      lastDate = DateToStr(DateAdd("ww",-1,strForumTimeAdjust))
   Case "Last2Weeks"
      lastDate = DateToStr(DateAdd("ww",-2,strForumTimeAdjust))
   Case "LastMonth"
      lastDate = DateToStr(DateAdd("m",-1,strForumTimeAdjust))
   Case "Last2Months"
      lastDate = DateToStr(DateAdd("m",-2,strForumTimeAdjust))
   Case Else
      lastDate = ""
End Select
Response.Write "    <script language=""JavaScript"" type=""text/javascript"">" & vbNewLine & _
   "    <!--" & vbNewLine & _
   "    function autoReload() {  document.ReloadFrm.submit()      }" & vbNewLine & _
   "    function SetLastDate()   {  document.LastDateFrm.submit() }" & vbNewLine & _
   "    function jumpTo(s) {  if (s.selectedIndex != 0) location.href = s.options[s.selectedIndex].value;return 1;}" & vbNewLine & _
   "    //defaultStatus = ""You last loaded this page on " & chkDate(DateToStr(strForumTimeAdjust)," ",true) & " (Forum Time)""" & vbNewLine & _
   "    // -->" & vbNewLine & _
   "    </script>" & vbNewLine
If IsEmpty(Session(strCookieURL & "last_here_date")) Then
   Session(strCookieURL & "last_here_date") = ReadLastHereDate(strDBNTUserName)
End If
If lastDate = "" Then
   lastDate = Session(strCookieURL & "last_here_date")
End If
If Request.Form("AllRead") = "Y" Then
   lastDate = ChkString(Request.Form("BuildTime"),"SQLString")
   '## The redundant line below is necessary, don't delete it.
   Session(strCookieURL & "last_here_date") = lastDate
   Session(strCookieURL & "last_here_date") = lastDate
   UpdateLastHereDate lastDate,strDBNTUserName
   ActiveSince = ""
End If
If strModeration = "1" and mLev > 2 Then
   UnModeratedPosts = CheckForUnmoderatedPosts("BOARD", 0, 0, 0)
End If
Dim strSubString, strSubArray, strBoardSubs, strCatSubs, strForumSubs, strTopicSubs
If MySubCount > 0 Then
   strSubString = PullSubscriptions(0,0,0)
   strSubArray  = Split(strSubString,";")
   If uBound(strSubArray) < 0 Then
      strBoardSubs = ""
      strCatSubs = ""
      strForumSubs = ""
      strTopicSubs = ""
   Else
      strBoardSubs = strSubArray(0)
      strCatSubs = strSubArray(1)
      strForumSubs = strSubArray(2)
      strTopicSubs = strSubArray(3)
   End If
End If
If mlev = 3 Then
   strSql = "SELECT FORUM_ID FROM " & strTablePrefix & "MODERATOR " & _
      " WHERE MEMBER_ID = " & MemberID
   Set rsMod = Server.CreateObject("ADODB.Recordset")
   rsMod.Open strSql, my_Conn, adOpenForwardOnly, adLockReadOnly, adCmdText
   If rsMod.EOF Then
      recModCount = ""
   Else
      allModData = rsMod.GetRows(adGetRowsRest)
      recModCount = UBound(allModData,2)
   End If
   RsMod.Close
   Set RsMod = Nothing
   If recModCount <> "" Then
      For x = 0 to recModCount
         If x = 0 Then
            ModOfForums = allModData(0,x)
         Else
            ModOfForums = ModOfForums & "," & allModData(0,x)
         End If
      Next
   Else
      ModOfForums = ""
   End If
Else
   ModOfForums = ""
End If
If strPrivateForums = "1" and mLev < 4 Then
   allAllowedForums = ""
   allowSql = "SELECT FORUM_ID, F_SUBJECT, F_PRIVATEFORUMS, F_PASSWORD_NEW"
   allowSql = allowSql & " FROM " & strTablePrefix & "FORUM"
   allowSql = allowSql & " WHERE F_TYPE = 0"
   allowSql = allowSql & " ORDER BY FORUM_ID"
   Set rsAllowed = Server.CreateObject("ADODB.Recordset")
   rsAllowed.Open allowSql, my_Conn, adOpenForwardOnly, adLockReadOnly, adCmdText
   If rsAllowed.EOF Then
      recAllowedCount = ""
   Else
      allAllowedData = rsAllowed.GetRows(adGetRowsRest)
      recAllowedCount = UBound(allAllowedData,2)
   End If
   rsAllowed.Close
   Set rsAllowed = Nothing
   If recAllowedCount <> "" Then
      fFORUM_ID = 0
      fF_SUBJECT = 1
      fF_PRIVATEFORUMS = 2
      fF_PASSWORD_NEW = 3
      For RowCount = 0 to recAllowedCount
         Forum_ID = allAllowedData(fFORUM_ID,RowCount)
         Forum_Subject = allAllowedData(fF_SUBJECT,RowCount)
         Forum_PrivateForums = allAllowedData(fF_PRIVATEFORUMS,RowCount)
         Forum_FPasswordNew = allAllowedData(fF_PASSWORD_NEW,RowCount)
         If mLev = 4 Then
            ModerateAllowed = "Y"
         ElseIf mLev = 3 and ModOfForums <> "" Then
            If (strAuthType = "nt") Then
               If (chkForumModerator(Forum_ID, Session(strCookieURL & "username")) = "1") Then ModerateAllowed = "Y" Else ModerateAllowed = "N"
            Else
               If (instr("," & ModOfForums & "," ,"," & Forum_ID & ",") > 0) Then ModerateAllowed = "Y" Else ModerateAllowed = "N"
            End If
         Else
            ModerateAllowed = "N"
         End If
         If chkForumAccessNew(Forum_PrivateForums,Forum_FPasswordNew,Forum_Subject,Forum_ID,MemberID) = true Then
            If allAllowedForums = "" Then
               allAllowedForums = Forum_ID
            Else
               allAllowedForums = allAllowedForums & "," & Forum_ID
            End If
         End If
      Next
   End If
   If allAllowedForums = "" Then allAllowedForums = 0
End If
'  ## Msg Icon & Poll Below
strSql = "SELECT F.FORUM_ID, " & _
   "F.F_SUBJECT, " & _
   "F.F_SUBSCRIPTION, " & _
   "F.F_STATUS, " & _
   "C.CAT_ID, " & _
   "C.CAT_NAME, " & _
   "C.CAT_SUBSCRIPTION, " & _
   "C.CAT_STATUS, " & _
   "T.T_STATUS, " & _
   "T.T_VIEW_COUNT, " & _
   "T.TOPIC_ID, " & _
   "T.T_ISPOLL, " &_
   "T.T_SUBJECT, " & _
   "T.T_AUTHOR, " & _
   "T.T_REPLIES, " & _
   "T.T_UREPLIES, " & _
   "M.M_NAME, " & _
   "T.T_LAST_POST_AUTHOR, " & _
   "T.T_LAST_POST, " & _
   "T.T_LAST_POST_REPLY_ID, " & _
   "MEMBERS_1.M_NAME AS LAST_POST_AUTHOR_NAME, " & _
   "T.T_MSGICON, " & _
   "F.F_PRIVATEFORUMS, " & _
   "F.F_PASSWORD_NEW, " & _
   "M.M_AVATAR_URL " & _
   "FROM " & strMemberTablePrefix & "MEMBERS M, " & _
   strTablePrefix & "FORUM F, " & _
   strTablePrefix & "TOPICS T, " & _
   strTablePrefix & "CATEGORY C, " & _
   strMemberTablePrefix & "MEMBERS MEMBERS_1 " & _
   "WHERE T.T_LAST_POST_AUTHOR = MEMBERS_1.MEMBER_ID "
'  ## Msg Icon & Poll Above
If strPrivateForums = "1" and mLev < 4 Then
   strSql = strSql & " AND F.FORUM_ID IN (" & allAllowedForums & ") "
End If
'#######    Begin UserGroup MOD     #######
    strDeniedForums = Session(strCookieURL & "DeniedForums" & MemberID)
    if strDeniedForums <> "" and strDeniedForums <> "-1" then
        strSql = strSql & " AND F.FORUM_ID NOT IN(" & Session(strCookieURL & "DeniedForums" & MemberID) & ") "
    end if
'#######     End UserGroup MOD      #######
strSql = strSql & "AND F.F_TYPE = 0 " & _
   "AND F.FORUM_ID = T.FORUM_ID " & _
   "AND C.CAT_ID = T.CAT_ID " & _
   "AND M.MEMBER_ID = T.T_AUTHOR " & _
   "AND (T.T_LAST_POST > '" & lastDate & "'"
If mlev <> 4 Then
   strSql = strSql & " AND ((T.T_AUTHOR <> " & MemberID &_
      " AND T.T_STATUS < 2)"  ' Ignore unapproved/held posts
   If mlev = 3 and ModOfForums <> "" Then
      strSql = strSql & " OR T.FORUM_ID IN (" & ModOfForums & ") "
   End If
   strSql = strSql & "  OR T.T_AUTHOR = " & MemberID & ")"
End If
If Group > 1 and strGroupCategories = "1" Then
   strSql = strSql & " AND (C.CAT_ID = 0"
   If recGroupCatCount <> "" Then
      For iGroupCat = 0 to recGroupCatCount
         strSql = strSql & " or C.CAT_ID = " & allGroupCatData(1, iGroupCat)
      Next
      strSql = strSql & ")"
   Else
      strSql = strSql & ")"
   End If
End If
strSql = strSql & ") "
strSql = strSql & " ORDER BY C.CAT_ORDER, C.CAT_NAME, F.F_ORDER, F.F_SUBJECT, T.T_LAST_POST DESC "
Set rs = Server.CreateObject("ADODB.Recordset")
If strDBType <> "mysql" Then rs.cachesize = 50
rs.Open strSql, my_Conn, adOpenForwardOnly, adLockReadOnly, adCmdText
If rs.EOF Then
   recActiveTopicsCount = ""
Else
   allActiveTopics = rs.GetRows(adGetRowsRest)
   recActiveTopicsCount = UBound(allActiveTopics,2)
   rs.Close
End If
Set rs = Nothing
'  ## Events Calendar Below
strSQL = "SELECT T.TOPIC_ID FROM " & strTablePrefix & "TOPICS AS T INNER JOIN " & strTablePrefix & "CAL_EVENTS AS C ON T.TOPIC_ID = C.TOPIC_ID WHERE T.T_LAST_POST > '" & lastDate & "' GROUP BY T.TOPIC_ID"
Set rsCal = Server.CreateObject("ADODB.Recordset")
rsCal.Open StrSql, My_conn
If not rsCal.EOF Then
   arrTopicID = rsCal.GetRows
   rsCal.Close
Else
   blnCalNoEvents = TRUE
End If
Set rsCal = Nothing
'  ## Events Calendar Above
Response.Write "      <table width=""100%"" border=""0"" cellspacing=""0"" cellpadding=""0"" align=""center"">" & vbNewLine & _
   "        <tr>" & vbNewLine & _
   "          <form name=""LastDateFrm"" action=""active.asp"" method=""post""><td>" & vbNewLine & _
   "          <font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>" & vbNewLine & _
   "          " & getCurrentIcon(strIconFolderOpen,"","") & " <a href=""default.asp"">COMMUNITY HOME</a><br />" & vbNewLine & _
   "          " & getCurrentIcon(strIconBar,"","") & getCurrentIcon(strIconFolderOpenTopic,"","") & " " & _
   "Active Topics Since " & vbNewLine
Response.Write "          <select name=""ShowSinceDateTime"" size=""1"" onchange=""SetLastDate();"">" & vbNewLine & _
   "           <option value=""LastVisit"""
If ActiveSince = "LastVisit" or ActiveSince = "" Then
   Response.Write " selected"
End If
Response.Write "> Last Visit on " & ChkDate(Session(strCookieURL & "last_here_date"),"",true) & " </option>" & vbNewLine & _
   "           <option value=""LastFifteen""" & chkSelect(ActiveSince,"LastFifteen") & "> Last 15 minutes</option>" & vbNewLine & _
   "           <option value=""LastThirty""" & chkSelect(ActiveSince,"LastThirty") & "> Last 30 minutes</option>" & vbNewLine & _
   "           <option value=""LastFortyFive""" & chkSelect(ActiveSince,"LastFortyFive") & "> Last 45 minutes</option>" & vbNewLine & _
   "           <option value=""LastHour""" & chkSelect(ActiveSince,"LastHour") & "> Last Hour</option>" & vbNewLine & _
   "           <option value=""Last2Hours""" & chkSelect(ActiveSince,"Last2Hours") & "> Last 2 Hours</option>" & vbNewLine & _
   "           <option value=""Last6Hours""" & chkSelect(ActiveSince,"Last6Hours") & "> Last 6 Hours</option>" & vbNewLine & _
   "           <option value=""Last12Hours""" & chkSelect(ActiveSince,"Last12Hours") & "> Last 12 Hours</option>" & vbNewLine & _
   "           <option value=""LastDay""" & chkSelect(ActiveSince,"LastDay") & "> Yesterday</option>" & vbNewLine & _
   "           <option value=""Last2Days""" & chkSelect(ActiveSince,"Last2Days") & "> Last 2 Days</option>" & vbNewLine & _
   "           <option value=""LastWeek""" & chkSelect(ActiveSince,"LastWeek") & "> Last Week</option>" & vbNewLine & _
   "           <option value=""Last2Weeks""" & chkSelect(ActiveSince,"Last2Weeks") & "> Last 2 Weeks</option>" & vbNewLine & _
   "           <option value=""LastMonth""" & chkSelect(ActiveSince,"LastMonth") & "> Last Month</option>" & vbNewLine & _
   "           <option value=""Last2Months""" & chkSelect(ActiveSince,"Last2Months") & "> Last 2 Months</option>" & vbNewLine & _
   "          </select>" & vbNewLine & _
   "          <input type=""hidden"" name=""Cookie"" value=""2"">" & vbNewLine & _
   "          </font>" & vbNewLine & _
   "          </td>" & vbNewLine & _
   "          </form>" & vbNewLine & _
   "          <td align=""center""> </td>" & vbNewLine & _
   "          <form name=""ReloadFrm"" action=""active.asp"" method=""post"">" & vbNewLine & _
   "          <td align=""right"">" & vbNewLine & _
   "          <font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>" & _
   "          <br />" & vbNewLine & _
   "          <select name=""RefreshTime"" size=""1"" onchange=""autoReload();"">" & vbNewLine & _
   "          <option value=""0""" & chkSelect(nRefreshTime,0) & ">Don't reload automatically</option>" & vbNewLine & _
   "           <option value=""1""" & chkSelect(nRefreshTime,1) & ">Reload page every minute</option>" & vbNewLine & _
   "           <option value=""2""" & chkSelect(nRefreshTime,2) & ">Reload page every 2 minutes</option>" & vbNewLine & _
   "           <option value=""5""" & chkSelect(nRefreshTime,5) & ">Reload page every 5 minutes</option>" & vbNewLine & _
   "           <option value=""10""" & chkSelect(nRefreshTime,10) & ">Reload page every 10 minutes</option>" & vbNewLine & _
   "           <option value=""15""" & chkSelect(nRefreshTime,15) & ">Reload page every 15 minutes</option>" & vbNewLine & _
   "          </select>" & vbNewLine & _
   "          <input type=""hidden"" name=""Cookie"" value=""1"">" & vbNewLine & _
   "          </font>" & vbNewLine & _
   "          </td>" & vbNewLine & _
   "          </form>" & vbNewLine & _
   "        </tr>" & vbNewLine & _
   "      </table>" & vbNewLine & _
   "      <font size=""" & strFooterFontSize & """><br /></font>" & vbNewLine & _
   "      <table border=""0"" width=""100%"" cellspacing=""0"" cellpadding=""0"" align=""center"">" & vbNewLine & _
   "        <tr>" & vbNewLine & _
   "          <td bgcolor=""" & strTableBorderColor & """>" & vbNewLine & _
   "            <table border=""0"" width=""100%"" cellspacing=""1"" cellpadding=""4"">" & vbNewLine & _
   "              <tr>" & vbNewLine & _
   "                <td align=""center"" bgcolor=""" & strHeadCellColor & """ valign=""middle""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strHeadFontColor & """>" & vbNewLine
If recActiveTopicsCount <> "" and (mLev > 0) Then
   Response.Write "                <form name=""MarkRead"" action=""active.asp"" method=""post"" style=""display:inline"">" & vbNewLine & _
      "                <input type=""hidden"" name=""AllRead"" value=""Y"">" & vbNewLine & _
      "                <input type=""hidden"" name=""BuildTime"" value=""" & DateToStr(strForumTimeAdjust) & """>" & vbNewLine & _
      "                <input type=""hidden"" name=""Cookie"" value=""2"">" & vbNewLine & _
      "                <acronym style=""border:none; text-decoration:none"" title=""Mark all topics as read""><input type=""image"" src=""" & strImageUrl & "icon_topic_all_read.png"" value=""Mark all read"" id=""submit1"" name=""Mark all topics as read"" border=""0""" & dWStatus("Mark all topics as read") & "></acronym></font></td>" & vbNewLine & _
      "                </form>" & vbNewLine
Else
   Response.Write "                 </font></td>" & vbNewLine
End If
Response.Write "                <td align=""center"" bgcolor=""" & strHeadCellColor & """><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """> </font></b></td>" & vbNewLine & _
   "                <td align=""center"" bgcolor=""" & strHeadCellColor & """><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strHeadFontColor & """>Topic</font></b></td>" & vbNewLine & _
   "                <td align=""center"" bgcolor=""" & strHeadCellColor & """><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strHeadFontColor & """>Author</font></b></td>" & vbNewLine & _
   "                <td align=""center"" bgcolor=""" & strHeadCellColor & """><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strHeadFontColor & """>Comments</font></b></td>" & vbNewLine & _
   "                <td align=""center"" bgcolor=""" & strHeadCellColor & """><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strHeadFontColor & """>Read</font></b></td>" & vbNewLine & _
   "                <td align=""center"" bgcolor=""" & strHeadCellColor & """><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strHeadFontColor & """>Last Poster</font></b></td>" & vbNewLine
If (mlev > 0) or (lcase(strNoCookies) = "1") Then
   Response.Write "                <td align=""center"" bgcolor=""" & strHeadCellColor & """><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strHeadFontColor & """>"
   If (mLev = 4 or mLev = 3) or (lcase(strNoCookies) = "1") Then
      If UnModeratedPosts > 0 Then
         UnModeratedFPosts = 0
         Response.Write "<a href=""moderate.asp"">" & getCurrentIcon(strIconFolderModerate,"View All UnModerated Posts","hspace=""0""") & "</a>"
      Else
         Response.Write(" ")
      End If
   Else
      Response.Write(" ")
   End If
   Response.Write "</font></b></td>" & vbNewLine
End If
Response.Write "              </tr>" & vbNewLine
If recActiveTopicsCount = "" Then
   Response.Write "              <tr>" & vbNewLine & _
      "                <td colspan=""8"" bgcolor=""" & strForumCellColor & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strForumFontColor & """><b>No Active Topics Found</b></font></td>" & vbNewLine & _
      "              </tr>" & vbNewLine
Else
   currForum = 0
   fDisplayCount = 0
   canAccess = 0
   fFORUM_ID = 0
   fF_SUBJECT = 1
   fF_SUBSCRIPTION = 2
   fF_STATUS = 3
   fCAT_ID = 4
   fCAT_NAME = 5
   fCAT_SUBSCRIPTION = 6
   fCAT_STATUS = 7
   fT_STATUS = 8
   fT_VIEW_COUNT = 9
   fTOPIC_ID = 10
   '  ## Poll Below
   fIS_POLL = 11
   '  ## Poll Above
   fT_SUBJECT = 12
   fT_AUTHOR = 13
   fT_REPLIES = 14
   fT_UREPLIES = 15
   fM_NAME = 16
   fT_LAST_POST_AUTHOR = 17
   fT_LAST_POST = 18
   fT_LAST_POST_REPLY_ID = 19
   fLAST_POST_AUTHOR_NAME = 20
   fT_MSGICON = 21
   fF_PRIVATEFORUMS = 22
   fF_PASSWORD_NEW = 23
   fM_AVATAR_URL = 24
   For RowCount = 0 to recActiveTopicsCount
      '## Store all the recordvalues in variables first.
      Forum_ID = allActiveTopics(fFORUM_ID,RowCount)
      Forum_Subject = allActiveTopics(fF_SUBJECT,RowCount)
      ForumSubscription = allActiveTopics(fF_SUBSCRIPTION,RowCount)
      Forum_Status = allActiveTopics(fF_STATUS,RowCount)
      Cat_ID = allActiveTopics(fCAT_ID,RowCount)
      Cat_Name = allActiveTopics(fCAT_NAME,RowCount)
      CatSubscription = allActiveTopics(fCAT_SUBSCRIPTION,RowCount)
      Cat_Status = allActiveTopics(fCAT_STATUS,RowCount)
      Topic_Status = allActiveTopics(fT_STATUS,RowCount)
      Topic_View_Count = allActiveTopics(fT_VIEW_COUNT,RowCount)
      Topic_ID = allActiveTopics(fTOPIC_ID,RowCount)
      Topic_Subject = allActiveTopics(fT_SUBJECT,RowCount)
      Topic_Author = allActiveTopics(fT_AUTHOR,RowCount)
      Topic_Replies = allActiveTopics(fT_REPLIES,RowCount)
      Topic_UReplies = allActiveTopics(fT_UREPLIES,RowCount)
      Member_Name = allActiveTopics(fM_NAME,RowCount)
      Topic_Last_Post_Author = allActiveTopics(fT_LAST_POST_AUTHOR,RowCount)
      Topic_Last_Post = allActiveTopics(fT_LAST_POST,RowCount)
      Topic_Last_Post_Reply_ID = allActiveTopics(fT_LAST_POST_REPLY_ID,RowCount)
      Topic_Last_Post_Author_Name = chkString(allActiveTopics(fLAST_POST_AUTHOR_NAME,RowCount),"display")
      Topic_MsgIcon = allActiveTopics(fT_MSGICON,RowCount)
      Forum_PrivateForums = allActiveTopics(fF_PRIVATEFORUMS,RowCount)
      Forum_FPasswordNew = allActiveTopics(fF_PASSWORD_NEW,RowCount)
      Member_Avatar = allActiveTopics(fM_AVATAR_URL,RowCount)
        strSqlAv = "SELECT M_AVATAR_URL FROM " & strMemberTablePrefix & "MEMBERS WHERE MEMBER_ID = " & Topic_Last_Post_Author
         Set rsLPost=my_Conn.Execute(strSqlAv)
         If not rsLPost.EOF Then
            strLPostAvatar=rsLPost("M_AVATAR_URL")
            rsLPost.Close
         End If
         Set rsLPost=Nothing
      '  ## Events Calendar Below
      blnEvent = False
      If not blnCalNoEvents Then
         For each ttID in arrTopicID
            If cLng(ttID) = cLng(TOPIC_ID) Then
               blnEvent = TRUE
               Exit For
            End If
         Next
      End If
      '  ## Events Calendar Above
      '  ## Poll Below
      IsPoll = allActiveTopics(fIS_POLL,RowCount)
      If IsPoll = 1 Then
         pollLink = "poll=1&"
      Else
         pollLink = ""
      End If
      '  ## Poll Above
      If mLev = 4 Then
         ModerateAllowed = "Y"
      ElseIf mLev = 3 and ModOfForums <> "" Then
         If (strAuthType = "nt") Then
            If (chkForumModerator(Forum_ID, Session(strCookieURL & "username")) = "1") Then ModerateAllowed = "Y" Else ModerateAllowed = "N"
         Else
            If (instr("," & ModOfForums & "," ,"," & Forum_ID & ",") > 0) Then ModerateAllowed = "Y" Else ModerateAllowed = "N"
         End If
      Else
         ModerateAllowed = "N"
      End If
      If ModerateAllowed = "Y" and Topic_UReplies > 0 Then
         Topic_Replies = Topic_Replies + Topic_UReplies
      End If
      fDisplayCount = fDisplayCount + 1
      If currForum <> Forum_ID Then
         Response.Write "              <tr>" & vbNewLine & _
            "                <td height=""20"" colspan=""7"" bgcolor=""" & strCategoryCellColor & """ valign=""middle""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strCategoryFontColor & """><a href=""default.asp?CAT_ID=" & Cat_ID & """><font color=""" & strCategoryFontColor & """><b>" & ChkString(Cat_Name,"display") & "</b></font></a> / <a href=""forum.asp?FORUM_ID=" & Forum_ID & """><font color=""" & strCategoryFontColor & """><b>" & ChkString(Forum_Subject,"display") & "</b></font></a></font></td>" & vbNewLine
         If (mlev > 0) or (lcase(strNoCookies) = "1") Then
            Response.Write "                <td align=""center"" bgcolor=""" & strCategoryCellColor & """ nowrap valign=""middle"">" & vbNewLine
            If (ModerateAllowed = "Y") or (lcase(strNoCookies) = "1") Then
               ForumAdminOptions
            Else
               If Cat_Status <> 0 and Forum_Status <> 0 Then
                  ForumMemberOptions
               Else
                  Response.Write "                 " & vbNewLine
               End If
            End If
            Response.Write "                </td>" & vbNewLine
         ElseIf (mLev = 3) Then
            Response.Write "                <td align=""center"" bgcolor=""" & strCategoryCellColor & """ nowrap valign=""middle""> </td>" & vbNewLine
         End If
         Response.Write "              </tr>" & vbNewLine
      End If
      Response.Write "              <tr>" & vbNewLine
      Response.Write "                <td bgcolor=""" & strForumCellColor & """ align=""center"" valign=""middle"">"
      Response.Write "<a href=""topic.asp?TOPIC_ID=" & Topic_ID & """>"
      If Cat_Status <> 0 and Forum_Status <> 0 and Topic_Status <> 0 Then
         If Topic_Status = 2 Then
            UnApprovedFound = "Y"
            Response.Write    getCurrentIcon(strIconFolderUnmoderated,"Topic Not Moderated","hspace=""0""") & "</a>" & vbNewLine
         ElseIf Topic_Status = 3 Then
            HeldFound = "Y"
            Response.Write    getCurrentIcon(strIconFolderHold,"Topic on Hold","hspace=""0""") & "</a>" & vbNewLine
            ' DEM --> end of code Added For topic moderation
         '  ## Events Calendar Below
         ElseIf blnEvent Then
            Response.Write getCurrentIcon(strCalIconEvent, strCalEvent,"")
         '  ## Events Calendar Above
         ElseIf lcase(strHotTopic) = "1" and Topic_Replies >= intHotTopicNum Then
            Response.Write getCurrentIcon(strIconFolderNewHot,"Hot Topic with New Posts","hspace=""0""") & "</a>" & vbNewLine
         ElseIf Topic_Last_Post < lastdate Then
            Response.Write getCurrentIcon(strIconFolder,"No New Posts","") & "</a>" & vbNewLine
         Else
            Response.Write getCurrentIcon(strIconFolderNew,"New Posts","") & "</a>" & vbNewLine
         End If
      Else
         If Cat_Status = 0 Then
            strAltText = "Category locked"
         ElseIf Forum_Status = 0 Then
            strAltText = "Forum locked"
         Else
            strAltText = "Topic locked"
         End If
         If Topic_Last_Post < lastdate Then
            Response.Write getCurrentIcon(strIconFolderLocked,strAltText,"hspace=""0""")
         Else
            Response.Write getCurrentIcon(strIconFolderNewLocked,strAltText,"hspace=""0""")
         End If
         Response.Write "</a>" & vbNewLine
      End If
      '  ## Message Icon Below
      Response.Write "                </td>" & vbNewLine & _
         "                <td bgcolor=""" & strForumCellColor & """ valign=""middle"" align=""center"">" & getCurrentIcon(getCurrentMsgIcon(Topic_MsgIcon),"","hspace=""0""") & "</td>" & vbNewLine & _
         "                <td bgcolor=""" & strForumCellColor & """ valign=""middle""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>"
      '  ## Message Icon Above
      '  ## Poll Below
         If IsPoll Then Response.Write "Poll: "
      '  ## Poll Above
      Response.Write "<span class=""spnMessageText""><a href=""topic.asp?TOPIC_ID=" & Topic_ID & """>" & ChkString(Topic_Subject,"title") & "</a></span> </font>" & vbNewLine
      If strShowPaging = "1" Then
         TopicPaging()
      End If
      Response.Write "                </td>" & vbNewLine & _
      "              <td bgcolor=""" & strForumCellColor & """ valign=""middle"" align=""center""><a href=""pop_profile.asp?mode=display&id="& TOPIC_AUTHOR & """><acronym style=""text-decoration:underline; border:none;"" title=""" & Member_Name & """><img src=""" & Member_Avatar & """ height=""50"" width=""50"" /></acronym></a><br /><font face=""" & strDefaultFontFace & """ size=""1"" & strDefaultFontSize & """" color=""" &  strForumFontColor & """><span class=""spnMessageText"">" & profileLink(chkString(Member_Name,"display"),Topic_Author) & "</span></font></td>" & vbNewLine
      if CLng(Topic_Replies) > 0 then
         response.write "                <td bgcolor=""" & strForumCellColor & """ valign=""middle"" align=""center""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strForumFontColor & """><span class=""spnMessageText""><acronym title=""Click here to see who has posted in this topic. (" & ChkString(Topic_Subject,"title") & ")""><a href=""JavaScript:openWindow3('pop_posted.asp?" & ArchiveLink & "Topic_ID=" & Topic_ID & "')""" & dWStatus("Who has posted?") & "><font size=""1"">Click to see who commented<br /></font>" & Topic_Replies & "</a></acronym></span></font></td>" & vbNewLine
      else
         response.write "                <td bgcolor=""" & strForumCellColor & """ valign=""middle"" align=""center""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strForumFontColor & """>" & Topic_Replies & "</font></td>" & vbNewLine
      end if
       Response.Write   "                <td bgcolor=""" & strForumCellColor & """ valign=""middle"" align=""center""> <font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" &  strForumFontColor & """>" & Topic_View_Count & "</font></td>" & vbNewLine
      If IsNull(Topic_Last_Post_Author) Then
         strLastAuthor = ""
      Else
         strLastAuthor = "<br />by: <a href=""pop_profile.asp?mode=display&id="& Topic_Last_Post_Author & """><acronym style=""text-decoration:underline; border:none;"" title=""" & Topic_Last_Post_Author_Name & """><img src=""" & strLPostAvatar & """ height=""50"" width=""50"" /></acronym></a>"
         If strJumpLastPost = "1" Then strLastAuthor = strLastAuthor & " " & DoLastPostLink
      End If
      Response.Write "                <td bgcolor=""" & strForumCellColor & """ valign=""middle"" align=""center"" nowrap><font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """ color=""" & strForumFontColor & """><b>" & ChkDate(Topic_Last_Post, "</b> " ,true) & strLastAuthor & "</font></td>" & vbNewLine
      If (mlev > 0) or (lcase(strNoCookies) = "1") Then
         Response.Write "                <td bgcolor=""" & strForumCellColor & """ valign=""middle"" align=""center"" nowrap><b><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """>" & vbNewLine
         If (ModerateAllowed = "Y") or (lcase(strNoCookies) = "1") Then
            Call TopicAdminOptions
         Else
            If  Cat_Status <> 0 and Forum_Status <> 0 and Topic_Status <> 0 Then
               Call TopicMemberOptions
            Else
               Response.Write "                 " & vbNewLine
            End If
         End If
         Response.Write "                </font></b></td>" & vbNewLine
      ElseIf (mLev = 3) Then
         Response.Write "                <td bgcolor=""" & strForumCellColor & """> </td>" & vbNewLine
      End If
      Response.Write "              </tr>" & vbNewLine
      currForum = Forum_ID
   Next
   If fDisplayCount = 0 Then
      Response.Write "              <tr>" & vbNewLine & _
         "                <td colspan=""" & aGetColspan(7,6) & """ bgcolor=""" & strForumCellColor & """><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """><b>No Active Topics Found</b></font></td>" & vbNewLine & _
         "              </tr>" & vbNewLine
   End If
End If
Response.Write "            </table>" & vbNewLine & _
   "          </td>" & vbNewLine & _
   "        </tr>" & vbNewLine & _
   "      </table>" & vbNewLine & _
   "      <table width=""100%"" border=""0"" align=""center"">" & vbNewLine & _
   "        <tr>" & vbNewLine & _
   "          <td align=""left"" width=""50%"">" & vbNewLine & _
   "            <table>" & vbNewLine & _
   "              <tr>" & vbNewLine & _
   "                <td>" & vbNewLine & _
   "                <p><font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """>" & vbNewLine & _
   "                " & getCurrentIcon(strIconFolderNew,"New Posts","align=""absmiddle""") & " New posts since last logon.<br />" & vbNewLine & _
   "                " & getCurrentIcon(strIconFolder,"Old Posts","align=""absmiddle""") & " Old Posts."
If lcase(strHotTopic) = "1" Then
   Response.Write (" (" & getCurrentIcon(strIconFolderHot,"Hot Topic","align=""absmiddle""") & " " & intHotTopicNum & " replies or more.)<br />" & vbNewLine)
End If
Response.Write "                " & getCurrentIcon(strIconFolderLocked,"Locked Topic","align=""absmiddle""") & " Locked topic.<br />" & vbNewLine
If HeldFound = "Y" Then
   Response.Write "                " & getCurrentIcon(strIconFolderHold,"Held Topic","align=""absmiddle""") & " Held Topic.<br />" & vbNewLine
End If
If UnapprovedFound = "Y" Then
   Response.Write "                " & getCurrentIcon(strIconFolderUnmoderated,"UnModerated Topic","align=""absmiddle""") & " UnModerated Topic.<br />" & vbNewLine
End If
Response.Write "                </font></p></td>" & vbNewLine & _
   "              </tr>" & vbNewLine & _
   "            </table>" & vbNewLine & _
   "          </td>" & vbNewLine & _
   "          <td align=""right"" valign=""top"" width=""50%"" nowrap>" & vbNewLine
%>
<!--#INCLUDE FILE="inc_jump_to.asp" -->
<%
Response.Write "        </td></tr><tr>" & vbNewline & _
   "          <td colspan=""" & sGetColspan(7,6) & """ bgColor=""" & strForumCellColor & """>" & vbNewline & _
"            <table width=""100%""  border=""1"" style=""border-collapse:collapse;"" cellpadding=""4"" cellspacing=""1"" bgColor=""" & strTableBorderColor & """>" & vbNewline & _
   "              <tr>" & vbNewline
Call DisplayBirthdays(30,0)
Response.Write "           </tr>" & vbNewLine & _
   "      </table></td></tr>" & vbNewLine & _
   "    <script language=""javascript"" type=""text/javascript"">" & vbNewLine & _
   "    <!--" & vbNewLine & _
   "    if (document.ReloadFrm.RefreshTime.options[document.ReloadFrm.RefreshTime.selectedIndex].value > 0) {" & vbNewline & _
   "  reloadTime = 60000 * document.ReloadFrm.RefreshTime.options[document.ReloadFrm.RefreshTime.selectedIndex].value" & vbNewLine & _
   "  self.setInterval('autoReload()', 60000 * document.ReloadFrm.RefreshTime.options[document.ReloadFrm.RefreshTime.selectedIndex].value)" & vbNewLine & _
   "    }" & vbNewLine & _
   "    //-->" & vbNewLine & _
   "    </script>" & vbNewLine
WriteFooter
Response.End

Sub ForumAdminOptions()
   If (ModerateAllowed = "Y") or (lcase(strNoCookies) = "1") Then
      If Cat_Status = 0 Then
         If mlev = 4 Then
            Response.Write "                <a href=""JavaScript:openWindow('pop_open.asp?mode=Category&CAT_ID=" & Cat_ID & "')"">" & getCurrentIcon(strIconFolderUnlocked,"Un-Lock Category","") & "</a>" & vbNewLine
         Else
            Response.Write "                " & getCurrentIcon(strIconFolderLocked,"Category Locked","") & vbNewLine
         End If
      Else
         If Forum_Status <> 0 Then
            Response.Write "                <a href=""JavaScript:openWindow('pop_lock.asp?mode=Forum&FORUM_ID=" & Forum_ID & "&CAT_ID=" & Cat_ID & "')"">" & getCurrentIcon(strIconFolderLocked,"Lock Forum","") & "</a>" & vbNewLine
         Else
            Response.Write "                <a href=""JavaScript:openWindow('pop_open.asp?mode=Forum&FORUM_ID=" & Forum_ID & "&CAT_ID=" & Cat_ID & "')"">" & getCurrentIcon(strIconFolderUnlocked,"Un-Lock Forum","") & "</a>" & vbNewLine
         End If
      End If
      If (Cat_Status <> 0 and Forum_Status <> 0) or (ModerateAllowed = "Y") Then
         Response.Write "                <a href=""post.asp?method=EditForum&FORUM_ID=" & Forum_ID & "&CAT_ID=" & Cat_ID & "&type=0"">" & getCurrentIcon(strIconFolderPencil,"Edit Forum Properties","hspace=""0""") & "</a>" & vbNewLine
      End If
      If mLev = 4 or lcase(strNoCookies) = "1" Then Response.Write("                <a href=""JavaScript:openWindow('pop_delete.asp?mode=Forum&FORUM_ID=" & Forum_ID & "&CAT_ID=" & Cat_ID & "')"">" & getCurrentIcon(strIconFolderDelete,"Delete Forum","") & "</a>" & vbNewLine)
      Response.Write "                <a href=""post.asp?method=Topic&FORUM_ID=" & Forum_ID & """>" & getCurrentIcon(strIconFolderNewTopic,"New Topic","") & "</a>" & vbNewLine
      If (strSubscription < 4 and strSubscription > 0) and (CatSubscription > 0) and ForumSubscription = 1 and strEmail = 1 Then
         If InArray(strForumSubs, Forum_ID) Then
            Response.Write ShowSubLink ("U", Cat_ID, Forum_ID, 0, "N")
         ElseIf strBoardSubs <> "Y" and not(InArray(strCatSubs,Cat_ID)) Then
            Response.Write ShowSubLink ("S", Cat_ID, Forum_ID, 0, "N")
         End If
      End If
   End If
End Sub

Sub ForumMemberOptions()
   If (mlev > 0) Then
      Response.Write "                <a href=""post.asp?method=Topic&FORUM_ID=" & Forum_ID & """>" & getCurrentIcon(strIconFolderNewTopic,"New Topic","") & "</a>" & vbNewLine
      If (strSubscription > 0 and strSubscription < 4) and CatSubscription > 0 and ForumSubscription = 1 and strEmail = 1 Then
         If InArray(strForumSubs, Forum_ID) Then
            Response.Write ShowSubLink ("U", Cat_ID, Forum_ID, 0, "N")
         ElseIf strBoardSubs <> "Y" and not(InArray(strCatSubs,Cat_ID)) Then
            Response.Write ShowSubLink ("S", Cat_ID, Forum_ID, 0, "N")
         End If
      End If
   End If
End Sub

Sub TopicAdminOptions()
   If Cat_Status = 0 Then
      Response.Write "                <a href=""JavaScript:openWindow('pop_open.asp?mode=Category&CAT_ID=" & Cat_ID & "')"">" & getCurrentIcon(strIconUnlock,"Un-Lock Category","hspace=""0""") & "</a>" & vbNewLine
   ElseIf Forum_Status = 0 Then
      Response.Write "                <a href=""JavaScript:openWindow('pop_open.asp?mode=Forum&FORUM_ID=" & Forum_ID & "&CAT_ID=" & Cat_ID & "')"">" & getCurrentIcon(strIconUnlock,"Un-Lock Forum","hspace=""0""") & "</a>" & vbNewLine
   ElseIf Topic_Status <> 0 Then
      Response.Write "                <a href=""JavaScript:openWindow('pop_lock.asp?mode=Topic&TOPIC_ID=" & Topic_ID & "&FORUM_ID=" & Forum_ID & "&CAT_ID=" & Cat_ID & "')"">" & getCurrentIcon(strIconLock,"Lock Topic","hspace=""0""") & "</a>" & vbNewLine
   Else
      Response.Write "                <a href=""JavaScript:openWindow('pop_open.asp?mode=Topic&TOPIC_ID=" & Topic_ID & "&FORUM_ID=" & Forum_ID & "&CAT_ID=" & Cat_ID & "')"">" & getCurrentIcon(strIconUnlock,"Un-Lock Topic","hspace=""0""") & "</a>" & vbNewLine
   End If
   If (ModerateAllowed = "Y") or (Cat_Status <> 0 and Forum_Status <> 0 and Topic_Status <> 0) Then
   '  ## Poll Below
      Response.Write "                <a href=""post.asp?" & pollLink & "method=EditTopic&TOPIC_ID=" & Topic_ID & "&FORUM_ID=" & Forum_ID & "&auth=" & Topic_Author & """>" & getCurrentIcon(strIconPencil,"Edit Topic","hspace=""0""") & "</a>" & vbNewLine
   End If
   Response.Write "                <a href=""JavaScript:openWindow('pop_delete.asp?" & pollLink & "mode=Topic&TOPIC_ID=" & Topic_ID & "&FORUM_ID=" & Forum_ID & "&CAT_ID=" & Cat_ID & "')"">" & getCurrentIcon(strIconTrashcan,"Delete Topic","hspace=""0""") & "</a>" & vbNewLine
   '  ## Poll Above
   If Topic_Status <= 1 Then
      Response.Write "                <a href=""post.asp?method=Reply&TOPIC_ID=" & Topic_ID & "&FORUM_ID=" & Forum_ID & """>" & getCurrentIcon(strIconReplyTopic,"Reply to Topic","hspace=""0""") & "</a>" & vbNewLine
   End If
   If Topic_Status > 1 Then
      TopicString = "TOPIC_ID=" & Topic_ID & "&CAT_ID=" & Cat_ID & "&FORUM_ID=" & Forum_ID
      Response.Write "                <a href=""JavaScript:openWindow('pop_moderate.asp?" & TopicString & "')"">" & getCurrentIcon(strIconFolderModerate,"Approve/Hold/Reject this Topic","hspace=""0""") & "</a>" & vbNewLine
   End If
   If (strSubscription < 4 and strSubscription > 0) and (CatSubscription > 0) and ForumSubscription > 0 and strEmail = 1 Then
      If InArray(strTopicSubs, Topic_ID) Then
         Response.Write " " & ShowSubLink ("U", Cat_ID, Forum_ID, Topic_ID, "N")
      ElseIf strBoardSubs <> "Y" and not(InArray(strForumSubs,Forum_ID) or InArray(strCatSubs,Cat_ID)) Then
         Response.Write " " & ShowSubLink ("S", Cat_ID, Forum_ID, Topic_ID, "N")
      End If
   End If
End Sub

Sub TopicMemberOptions()
   If (Topic_Status > 0 and Topic_Author = MemberID) or (ModerateAllowed = "Y") Then
      '  ## Poll Below
      Response.Write "                <a href=""post.asp?" & pollLink & "method=EditTopic&TOPIC_ID=" & Topic_ID & "&FORUM_ID=" & Forum_ID & """>" & getCurrentIcon(strIconPencil,"Edit Topic","hspace=""0""") & "</a>" & vbNewLine
   End If
   If (Topic_Status > 0 and Topic_Author = MemberID and Topic_Replies = 0) or (ModerateAllowed = "Y") Then
      Response.Write "                <a href=""JavaScript:openWindow('pop_delete.asp?" & pollLink & "mode=Topic&TOPIC_ID=" & Topic_ID & "&FORUM_ID=" & Forum_ID & "&CAT_ID=" & Cat_ID & "')"">" & getCurrentIcon(strIconTrashcan,"Delete Topic","hspace=""0""") & "</a>" & vbNewLine
      '  ## Poll Above
   End If
   If Topic_Status <= 1 Then
      Response.Write "                <a href=""post.asp?method=Reply&TOPIC_ID=" & Topic_ID & "&FORUM_ID=" & Forum_ID & """>" & getCurrentIcon(strIconReplyTopic,"Reply to Topic","hspace=""0""") & "</a>" & vbNewLine
   End If
   If (strSubscription < 4 and strSubscription > 0) and (CatSubscription > 0) and ForumSubscription > 0 and strEmail = 1 Then
      If InArray(strTopicSubs, Topic_ID) Then
         Response.Write " " & ShowSubLink ("U", Cat_ID, Forum_ID, Topic_ID, "N")
      ElseIf strBoardSubs <> "Y" and not(InArray(strForumSubs,Forum_ID) or InArray(strCatSubs,Cat_ID)) Then
         Response.Write " " & ShowSubLink ("S", Cat_ID, Forum_ID, Topic_ID, "N")
      End If
   End If
End Sub

Sub TopicPaging()
   mxpages = (Topic_Replies / strPageSize)
   If mxPages <> cLng(mxPages) Then
      mxpages = int(mxpages) + 1
   End If
   If mxpages > 1 Then
      Response.Write "                  <table border=""0"" cellspacing=""0"" cellpadding=""0"">" & vbNewLine & _
         "                    <tr>" & vbNewLine & _
         "                      <td valign=""bottom""><font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """>" & getCurrentIcon(strIconPosticon,"","align=""absmiddle""") & "</font></td>" & vbNewLine
      For counter = 1 to mxpages
         ref = "                      <td align=""right"" valign=""bottom"" bgcolor=""" & strForumCellColor  & """><font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """>"
         If ((mxpages > 9) and (mxpages > strPageNumberSize)) or ((counter > 9) and (mxpages < strPageNumberSize)) Then
            ref = ref & " "
         End If
         ref = ref & widenum(counter) & "<span class=""spnMessageText""><a href=""topic.asp?"
         ref = ref & ArchiveLink
         ref = ref & "TOPIC_ID=" & Topic_ID
         ref = ref & "&whichpage=" & counter
         ref = ref & """>" & counter & "</a></span></font></td>"
         Response.Write ref & vbNewLine
         If counter mod strPageNumberSize = 0 and counter < mxpages Then
            Response.Write "                    </tr>" & vbNewLine & _
               "                    <tr>" & vbNewLine & _
               "                      <td> </td>" & vbNewLine
         End If
      Next
      Response.Write "                    </tr>" & vbNewLine & _
         "                  </table>" & vbNewLine
   End If
End Sub

Function DoLastPostLink()
   If Topic_Replies < 1 or Topic_Last_Post_Reply_ID = 0 Then
      DoLastPostLink = "<a href=""topic.asp?" & ArchiveLink & "TOPIC_ID=" & Topic_ID & """>" & getCurrentIcon(strIconLastpost,"Jump to Last Post","align=""absmiddle""") & "</a>"
   ElseIf Topic_Last_Post_Reply_ID <> 0 Then
      PageLink = "whichpage=-1&"
      AnchorLink = "&REPLY_ID="
      DoLastPostLink = "<a href=""topic.asp?" & ArchiveLink & PageLink & "TOPIC_ID=" & Topic_ID & AnchorLink & Topic_Last_Post_Reply_ID & """>" & getCurrentIcon(strIconLastpost,"Jump to Last Post","align=""absmiddle""") & "</a>"
   Else
      DoLastPostLink = ""
   End If
End Function

function aGetColspan(lIN, lOUT)
   If (mlev > 0 or strNoCookies = "1") Then
      lOut = lOut + 1
   End If
   If lOut > lIn Then
      aGetColspan = lIN
   Else
      aGetColspan = lOUT
   End If
End Function
Sub DoHideCategory(intCatId)
   HideForumCat = strUniqueID & "HideCat" & intCatId
   If Request.QueryString(HideForumCat) = "Y" Then
      Response.Cookies(HideForumCat) = "Y"
      Response.Cookies(HideForumCat).Expires = dateAdd("d", 30, strForumTimeAdjust)
   Else
      If Request.QueryString(HideForumCat) = "N" Then
         Response.Cookies(HideForumCat) = "N"
         Response.Cookies(HideForumCat).Expires = dateadd("d", -2, strForumTimeAdjust)
      End If
   End If
End sub
%>

quote:

---

Originally posted by HuwR

Active.asp is split by Forum not category, so you would need to collapse if by forum. I'm not sure that it really makes sense though as the categories and foums are not fixed like they are on default.asp, they change constantantly based on what has been posted.

---

Well, duh! It is "forums" on active.asp rather than categories! LOL

Anyway, I have Marcel's "Blog" mod installed and let's say there are a lot of members blogging but also a lot of members who don't like the clutter of all of the blogs listed on active.asp. They could simply collapse the entire "Blog" forum.

And, there is also a "DIY Craft" forum. Let's say that some members find all of the posts on that forum as merely clutter.

And, then there's the "Homeschool" and "Tech Talk" forums that some just don't care for either.

So see, this could truly be a great thing!