Snitz Forums 2000
Snitz Forums 2000
Home | Profile | Register | Active Topics | Members | Search | FAQ
Username:
 Password:
Save Password
Forgot your Password?

 All Forums
 Help Groups for Snitz Forums 2000 Users
 Help: MOD Implementation
 Change Username Mod Caused MAJOR Error		  New Topic
 Printer Friendly
Author Previous Topic Topic Next Topic  

MaGraham
Senior Member

USA
1297 Posts
Posted - 19 January 2013 :  18:19:47  Show Profile  Reply with Quote

I changed my username using this mod and chose the option to change the username in all of my previous posts. However; it's still displaying my former username but I have to log in using the new username.

And now, NONE of the graphics I used in the forum titles/names, when I created new forums, are displaying. And that's really huge for me! I use graphics on ALL of my forums titles/names that display on the default.asp. Here's just one example.

For a forum about sharing tips and help with photo-editing software programs, I created the following forum and placed the graphic below just under the forum name as indicated below.

PHOTOSHOP (OR SIMILAR) TIPS


So, this issue is affecting my entire default.asp page! I don't understand this at all. Those links to the graphics do not include my user name. Those links all point to the forum/image directory or to another directory.

Oh I hope someone is able to figure this one out for me. Please!

"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Edited by - MaGraham on 19 January 2013 19:00:03

MaGraham
Senior Member

USA
1297 Posts
Posted - 19 January 2013 :  19:51:09  Show Profile
I just now realized that NO pictures whatsoever are displaying now on ANY of the forums/topics/posts. The ONLY images displaying are the little smilies. NONE of the images members are posting and NONE of the ones in members' signatures are displaying.

Any ideas with this? Anyone?

The only two things I did prior to this is to run the database file Carefree created for me to run in order for the "Change Username Mod" to work and when it did work, I changed my username. That's all I did prior to this happening.

The links to all of the images work fine when inserted into a new browser, but none of the images will display anywhere within my forum.

And for a brief, very brief, time after changing my username. . .my NEW username displayed. It's not now. In members.asp it now displays in the correct position alphabetically, but that's obviously not correct since it's still displaying the previous username.
"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Edited by - MaGraham on 19 January 2013 20:01:55
Go to Top of Page

MaGraham
Senior Member

USA
1297 Posts
Posted - 19 January 2013 :  20:32:46  Show Profile

Okay, I think I may have found a clue! Since my domain has the word "the" in its name, that is somehow getting changed in the links.

Does this help anyone? Is this because of the database I ran that Carefree shared here? http://forum.snitz.com/forum/topic.asp?TOPIC_ID=70411

I'm asking because of the "the" in the database.

Can someone tell me if I am at least in the SAME ballpark?
"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Edited by - MaGraham on 19 January 2013 20:33:27
Go to Top of Page

MaGraham
Senior Member

USA
1297 Posts
Posted - 19 January 2013 :  20:47:23  Show Profile

Perhaps I should explain a bit more. My username was actually the name of the domain, thefriendshipplace.com. My username was The Friendship Place. I changed it to FriendshipPlace.

So, I think that is now causing a problem with ALL of the links on my forum.

I just now tried to post a link and it displayed like this in a post:
http://www.theThe Friendship Place.com. It displayed the extra "the" and capital letters as well.

Obviously, ALL of the images, whether on the default.asp or in a post, have the same problem now.

"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Edited by - MaGraham on 19 January 2013 20:53:49
Go to Top of Page

MaGraham
Senior Member

USA
1297 Posts
Posted - 19 January 2013 :  21:58:25  Show Profile

Well, it appears that I am just talking to myself with this (lol) but here's more info.

The links created automatically when the Snitz Forum was installed (those in the menu, etc.) and those generated when a forum is created still work fine, but NONE of the other links work (links behind a picture on the default.asp or in any of the posts).

"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Go to Top of Page

Carefree
Advanced Member

Philippines
4222 Posts
Posted - 20 January 2013 :  01:39:32  Show Profile
quote:
Okay, I think I may have found a clue! Since my domain has the word "the" in its name, that is somehow getting changed in the links.

I know what's happening, it's being replaced in the bad word table due to that username change routine. The old code had the username values interchanged. Here's a replacement file. For your interim situation, just use the bad word filter link from the admin console and delete the cause.

"changeme.asp"


<%
'###############################################################################
'##
'## 	                Snitz Forums 2000 v3.4.07
'##
'###############################################################################
'##
'## Copyright © 2000-09 Michael Anderson, Pierre Gorissen,
'## 	                Huw Reddick and Richard Kinser
'##
'## This program is free. You can redistribute and/or modify it under the
'## terms of the GNU General Public License as published by the Free Software
'## Foundation; either version 2 or (at your option) any later version.
'##
'## All copyright notices regarding Snitz Forums 2000 must remain intact in
'## the scripts and in the HTML output.  The "powered by" text/logo with a
'## link back to http://forum.snitz.com in the footer of the pages MUST
'## remain visible when the pages are viewed on the internet or intranet.
'##
'## This program is distributed in the hope that it will be useful but
'## WITHOUT ANY WARRANTY; without even an implied warranty of MERCHANTABILITY
'## or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
'## for more details.
'##
'## You should have received a copy of the GNU General Public License along
'## with this program; if not, write to:
'##
'##		        Free Software Foundation, Inc.
'##		        59 Temple Place, Suite 330
'##		        Boston, MA 02111-1307
'##
'## Support can be obtained from our support forums at:
'##
'## 		        http://forum.snitz.com
'##
'## Correspondence and marketing questions can be sent to:
'##
'## 		        manderson@snitz.com
'##
'###############################################################################
'##
'## Based on Kyodai's Points' Namechange
'##
'###############################################################################
%>
<!--#INCLUDE FILE="config.asp"-->
<!--#INCLUDE FILE="inc_sha256.asp"-->
<!--#INCLUDE FILE="inc_header.asp" -->
<!--#INCLUDE FILE="inc_func_member.asp" -->
<%
strSql = "SELECT MEMBER_ID, M_CHANGEDNAME FROM " & strMemberTablePrefix & "MEMBERS WHERE MEMBER_ID=" & MemberID
Set rs = my_Conn.Execute (strSql)
If NOT (rs.BOF or rs.EOF) Then
	If rs("M_CHANGEDNAME") > "" and MemberID <> intAdminMemberID Then
		rs.Close
		Set rs = Nothing
		Err_Msg = "Error: You already changed your username, it cannot be changed again."
		Response.Write	"<table align=""center"" width=""75%"" bgColor=""" & strPageBGColor & """ style=""border-collapse:collapse;"" border=""1"">" & vbNewLine & _
			"	<tr height=""60"" valign=""middle"">" & vbNewLine & _
			"		<td align=""left"" width=""100%"" bgColor=""" & strForumCellColor & """>" & vbNewLine & _
			"			<font size=""" & strDefaultFontSize & """ color=""" & strForumFontColor & """ face=""" & strDefaultFontFace & """>" & Err_Msg & vbNewLine & _
			"			</font>" & vbNewLine & _
			"		</td>" & vbNewLine & _
			"	</tr>" & vbNewLine & _
			"</table>" & vbNewLine & _
			"<meta http-equiv=""Refresh"" content=""3; URL=default.asp"">" & vbNewLine			
		WriteFooter
		Response.End
	End If
	Set rs = Nothing
End If
If Request.Form("DoIt") <> "ChangeMe" Then
	Response.Write "<form action=""ChangeMe.asp"" method=""post"">" & vbNewLine & _
		"<input type=""hidden"" name=""DoIt"" value=""ChangeMe"">" & vbNewLine & _
		"<table align=""center"" width=""80%"" style=""border-collapse:collapse;"" border=""1"" bgColor=""" & strPageBGColor & """ cellspacing=""1"" cellpadding=""3"">" & vbNewLine & _
		"	<tr height=""40"" valign=""middle"">" & vbNewLine & _
		"		<td align=""center"" colspan=""2"" width=""100%"" bgColor=""" & strCategoryCellColor & """>" & vbNewLine & _
		"			<font face=""" & strDefaultFontFace & """ color=""" & strHeadFontColor & """ size=""" & strHeaderFontSize+2 & """><b>User Name Changer</b>" & vbNewLine & _
		"			</font>" & vbNewLine & _
		"		</td>" & vbNewLine & _
		"	</tr>" & vbNewLine & _
		"	<tr valign=""middle"">" & vbNewLine & _
		"		<td align=""right"" width=""50%"" bgColor=""" & strPopupTableColor & """>" & vbNewLine & _
		"			<font face=""" & strDefaultFontFace & """ color=""" & strHeadFontColor & """ size=""" & strHeaderFontSize & """>Current Name:" & vbNewLine & _
		"			</font>" & vbNewLine & _
		"		</td>" & vbNewLine & _
		"		<td align=""left"" width=""50%"" bgColor=""" & strPopupTableColor & """>" & vbNewLine & _
		"			<font face=""" & strDefaultFontFace & """ color=""" & strForumFontColor & """ size=""" & strDefaultFontSize & """>" & strDBNTUserName & vbNewLine & _
		"			</font>" & vbNewLine & _
		"		</td>" & vbNewLine & _
		"	</tr>" & vbNewLine & _
		"	<tr valign=""middle"">" & vbNewLine & _
		"		<td align=""right"" width=""50%"" bgColor=""" & strPopupTableColor & """>" & vbNewLine & _
		"			<font face=""" & strDefaultFontFace & """ color=""" & strHeadFontColor & """ size=""" & strHeaderFontSize & """>Desired Name:" & vbNewLine & _
		"			</font>" & vbNewLine & _
		"		</td>" & vbNewLine & _
		"		<td align=""left"" width=""50%"" bgColor=""" & strPopupTableColor & """>" & vbNewLine & _
		"			<font face=""" & strDefaultFontFace & """ color=""" & strForumFontColor & """ size=""" & strDefaultFontSize & """>" & vbNewLine & _
		"				<input type=""text"" name=""NewUserName"" size=""50"" maxlength=""75"">" & vbNewLine & _
		"			</font>" & vbNewLine & _
		"		</td>" & vbNewLine & _
		"	</tr>" & vbNewLine & _
		"	<tr valign=""middle"">" & vbNewLine & _
		"		<td align=""right"" width=""50%"" bgColor=""" & strPopupTableColor & """>" & vbNewLine & _
		"			<font face=""" & strDefaultFontFace & """ color=""" & strHeadFontColor & """ size=""" & strHeaderFontSize & """>Replace UserName within Posts?" & vbNewLine & _
		"			</font>" & vbNewLine & _
		"		</td>" & vbNewLine & _
		"		<td align=""left"" width=""50%"" bgColor=""" & strPopupTableColor & """>" & vbNewLine & _
		"			<font face=""" & strDefaultFontFace & """ color=""" & strForumFontColor & """ size=""" & strDefaultFontSize & """>" & vbNewLine & _
		"				<input type=""radio"" class=""radio"" name=""Retain"" value=""Yes""" & chkRadio(Retain,"Yes",true) & ">Yes" & _
		"				<input type=""radio"" class=""radio"" name=""Retain"" value=""No""" & chkRadio(Retain,"No",true) & ">No" & _
		"			</font>" & vbNewLine & _
		"		</td>" & vbNewLine & _
		"	</tr>" & vbNewLine & _
		"	<tr valign=""middle"">" & vbNewLine & _
		"		<td align=""left"" colspan=""2"" width=""100%"" bgColor=""" & strAltForumCellColor & """>" & vbNewLine & _
		"			<font face=""" & strDefaultFontFace & """ color=""" & strForumFontColor & """ size=""" & strDefaultFontSize & """><br>" & vbNewLine & _
		"				1.  You can only change your username <b>ONCE</b>, so be sure before doing so.<br>" & vbNewLine & _
		"				2.  Do <b>NOT</b> use your real name, phone number or anything else you might regret.<br>" & vbNewLine & _
		"				3.  Dots or other special characters are <b>NOT</b> available in your new Username; however, spaces are allowed.<br>" & vbNewLine & _
		"				4.  You will <b>NOT</b> be able to log in with your current Username after the change.<br>" & vbNewLine & _
		"				5.  There is <b>NO</b> confirmation so TRIPLE check for typos before submitting.<br><br>" & vbNewLine & _
		"			</font>" & vbNewLine & _
		"		</td>" & vbNewLine & _
		"	</tr>" & vbNewLine & _
		"	<tr valign=""middle"">" & vbNewLine & _
		"		<td align=""center"" colspan=""2"" width=""100%"" bgColor=""" & strPageBGColor & """>" & vbNewLine & _
		"			<input type=""Submit"" value=""Change Name"" name=""Submit"">" & vbNewLine & _
		"		</td>" & vbNewLine & _
		"	</tr>" & vbNewLine & _
		"</table>" & vbNewLine & _
		"</form>" & vbNewLine
Else		 
	If NOT IsValidString(trim(Request.Form("NewUserName"))) Then
		Err_Msg = "<br><br><li>You may not use any of these characters in your User Name  !#$%^&*()=+{}[]|\;:/?>,<'.</li>"
		GoError(Err_Msg)
	End If
	If Request.Form("NewUserName") = "" or len(Request.Form("NewUserName")) <=2 Then
		Err_Msg = "<br><br><li>Please enter a valid username. Minimum length is 2 characters.</li>" & vbNewLine & _
		GoError(Err_Msg)
	End If
	strSql = "SELECT M_NAME FROM " & strMemberTablePrefix & "MEMBERS WHERE M_NAME = '" & ChkString(Trim(Request.Form("NewUserName")), "SQLString") &"'"
	Set rs = my_Conn.Execute(strSql)
	If NOT (rs.BOF or rs.EOF) Then
		Err_Msg = "<br><br><li>Error: Username is already taken.</li>"
		rs.Close
		GoError(Err_Msg)
	End If
	rs.Close
	Set rs = Nothing
	strSql = "SELECT M_NAME FROM " & strMemberTablePrefix & "MEMBERS_PENDING WHERE M_NAME = '" & ChkString(Trim(Request.Form("NewUserName")), "SQLString") &"'"
	Set rs = my_Conn.Execute(strSql)
	If NOT (rs.BOF or rs.EOF) Then
		Err_Msg = "<br><br><li>Error: Username is already taken.</li>"
		rs.Close
		GoError(Err_Msg)
	End If
	rs.Close
	Set rs = Nothing
	strSql = "SELECT M_CHANGEDNAME FROM " & strMemberTablePrefix & "MEMBERS WHERE MEMBER_ID=" & MemberID
	Set rs = my_Conn.Execute (strSql)
	If NOT (rs.BOF or rs.EOF) Then
		If rs("M_CHANGEDNAME") > "" and MemberID<>intAdminMemberID Then
			Err_Msg = "<br><br><li>Error: You already changed your username, it cannot be changed again.</li>"
			rs.Close
			Set rs = Nothing
			GoError(Err_Msg)
		End If
		Set rs = Nothing
	End If
	strSql = "SELECT WORDLIST FROM " & strTablePrefix & "COMMON WHERE WORDLIST='" & chkString(Request.Form("NewUserName"), "SQLString") & "'"
	Set rs=my_Conn.Execute(strSql)
	if not rs.EOF Then 
		Err_Msg = "<br><br><li>Requested username is too common, please select another.</li>"
		rs.Close
		Set rs = Nothing
		GoError(Err_Msg)
	End If
	Set rs = Nothing
	If Request.Form("Retain") = "Yes" then
		strSql = "INSERT INTO " & strTablePrefix & "BADWORDS (B_REPLACE, B_BADWORD) VALUES ('" & chkString(Request.Form("NewUserName"), "SQLString") & "', '" & strDBNTUserName & "')"
		my_Conn.Execute(strSql)
	End if
	strSql = "UPDATE "& strMemberTablePrefix & "MEMBERS SET M_NAME='" & chkString(Request.Form("NewUserName"), "SQLString") & "', M_CHANGEDNAME='" & strDBNTUserName & "' WHERE MEMBER_ID=" & MemberID
	my_Conn.Execute(strSql)
	Response.Write "<br>Your username has been changed.  You must logout and login using the new name."
	Call ClearCookies()
	LoginStatus = 0
	Response.Write	"<meta http-equiv=""Refresh"" content=""3; URL=default.asp"">" & vbNewLine
End If

Function GoError(Err_Msg)
	Response.Write	"<table align=""center"" width=""75%"" bgColor=""" & strPageBGColor & """ style=""border-collapse:collapse;"" border=""1"">" & vbNewLine & _
		"	<tr height=""60"" valign=""middle"">" & vbNewLine & _
		"		<td align=""left"" width=""100%"" bgColor=""" & strForumCellColor & """>" & vbNewLine & _
		"			<font size=""" & strDefaultFontSize & """ color=""" & strForumFontColor & """ face=""" & strDefaultFontFace & """>" & Err_Msg & vbNewLine & _
		"				<p><a href=""JavaScript:history.go(-1)"">Go Back To Edit Data</a></p>" & vbNewLine & _
		"			</font>" & vbNewLine & _
		"		</td>" & vbNewLine & _
		"	</tr>" & vbNewLine & _
		"</table>" & vbNewLine
	WriteFooter
	Response.End
End Function

Function IsValidString(sValidate)
	Dim sInvalidChars
	Dim bTemp
	Dim i 
	sInvalidChars = "!#$%^&*()=+{}[]|\;:/?>,<'."
	For i = 1 To Len(sInvalidChars)
		If InStr(sValidate, Mid(sInvalidChars, i, 1)) > 0 Then bTemp = True
		If bTemp then Exit For
	Next
	For i = 1 to Len(sValidate)
		If Asc(Mid(sValidate, i, 1)) = 160 Then bTemp = True
		If bTemp Then Exit For
	Next
	If NOT bTemp Then
		bTemp = (len(sValidate) <> len(Trim(sValidate)))
	End If
	IsValidString = Not bTemp
End Function
WriteFooter
%>
Edited by - Carefree on 20 January 2013 01:41:03
Go to Top of Page

MaGraham
Senior Member

USA
1297 Posts
Posted - 20 January 2013 :  15:11:13  Show Profile

I am just now getting a chance to come back and thank you, Carefree! ALL images are displaying PERFECT now!

You're the BEST! Thank you so much!!
"Do all the good you can, by all the means you can, in all the ways you can, at all the times you can, to all the people you can, as long as ever you can." - John Wesley
Go to Top of Page

Carefree
Advanced Member

Philippines
4222 Posts
Posted - 20 January 2013 :  23:22:19  Show Profile
Good enough.
Go to Top of Page
  Previous Topic Topic Next Topic  
 New Topic
 Printer Friendly
Jump To:
Snitz Forums 2000 © 2000-2021 Snitz™ Communications Go To Top Of Page
This page was generated in 0.31 seconds. Powered By: Snitz Forums 2000 Version 3.4.07