Snitz Forums 2000 - Bug + fix: pop

The fix I posted before will correct all issues of repeated posts subscriptions, by clicking the various subscription links, except when you try to click the link to subscribe a topic to which you already had subscribed. In order to fix it for this situation too, two changes to in pop_subscriptio.asp are needed.

Change 1. Around line#83, where you now have


elseif (sublevel = "TOPIC" or sublevel = "FORUM") and (CheckSubscriptionCount("CAT", Member_ID, CatId, 0, 0) > 0) then
	SendHigherLevelMsg "CAT", CatId
elseif sublevel = "TOPIC"  and (CheckSubscriptionCount("FORUM", Member_ID, CatID, ForumID, 0) > 0) then
	SendHigherLevelMsg "FORUM", ForumId
else
	' Delete any lower subscriptions to prevent duplicates emails.....
	if SubLevel = "FORUM" or SubLevel = "CAT" or SubLevel = "BOARD" then

Replace it by


elseif sublevel = "TOPIC"  and (CheckSubscriptionCount("FORUM", Member_ID, CatID, ForumID, 0) > 0) then
	SendHigherLevelMsg "FORUM", ForumId
elseif sublevel = "TOPIC"  and (CheckSubscriptionCount("TOPIC", Member_ID, CatID, ForumID, TopicID) > 0) then
	SendHigherLevelMsg "TOPIC", ForumId
else
	' Delete any lower subscriptions to prevent duplicates emails.....
        if SubLevel = "FORUM" or SubLevel = "CAT" or SubLevel = "BOARD" then

Then another change is needed in the function SendHigherLevelMessage. I will post the full code, highlighting the changes

Replace the current function


sub SendHigherLevelMsg(SubLevel, Id)
	' -- If an overriding subscription is found, return the appropriate error message.
	dim rs
	Response.Write	"You currently are subscribed to "
	if sublevel = "BOARD" then
		Response.Write "<br />all posts in " & strForumTitle & ""
	elseif sublevel = "CAT" then
		strSql = "SELECT CAT_NAME "
		strSql = strSql & "FROM " & strTablePrefix & "CATEGORY "
		strSql = strSql & "WHERE CAT_ID = " & Id

	        set rs = my_Conn.Execute (strSql)
		strCategory = rs("CAT_NAME")

		rs.close
		set rs = nothing

		Response.Write	"<br />all posts in "
		Response.Write	"<br />" & strCategory

	elseif sublevel = "FORUM" then
		strSql = "SELECT F_SUBJECT "
		strSql = strSql & "FROM " & strTablePrefix & "FORUM "
		strSql = strSql & "WHERE FORUM_ID = " & Id

	        set rs = my_Conn.Execute (strSql)
		strForum = rs("F_SUBJECT")

		rs.close
		set rs = nothing

		Response.Write	"<br />all posts in "
		Response.Write	"<br />" & strForum

	end if
	Response.Write	"<br />This will also mail you notification at the level you requested.</font></p>" & vbNewline & _
			"      <script language=""javascript1.2"">self.opener.location.reload();</script>" & vbNewLine
end sub


sub SendHigherLevelMsg(SubLevel, Id)
	' -- If an overriding subscription is found, return the appropriate error message.
	dim rs
	Response.Write	"You currently are subscribed to "
	if sublevel = "BOARD" then
		Response.Write "<br />all posts in " & strForumTitle & ""
	elseif sublevel = "CAT" then
		strSql = "SELECT CAT_NAME "
		strSql = strSql & "FROM " & strTablePrefix & "CATEGORY "
		strSql = strSql & "WHERE CAT_ID = " & Id

	        set rs = my_Conn.Execute (strSql)
		strCategory = rs("CAT_NAME")

		rs.close
		set rs = nothing

		Response.Write	"<br />all posts in "
		Response.Write	"<br />" & strCategory

	elseif sublevel = "FORUM" then
		strSql = "SELECT F_SUBJECT "
		strSql = strSql & "FROM " & strTablePrefix & "FORUM "
		strSql = strSql & "WHERE FORUM_ID = " & Id

	        set rs = my_Conn.Execute (strSql)
		strForum = rs("F_SUBJECT")

		rs.close
		set rs = nothing

		Response.Write	"<br />all posts in "
		Response.Write	"<br />" & strForum

	ElseIf sublevel="TOPIC" Then
                Response.Write	"<br />this topic."       
	end If
	
	If sublevel <> "TOPIC" Then
	   Response.Write	"<br />This will also mail you notification at the level you requested." & vbNewline 
	End If
	
	Response.Write 	"</font></p><script language=""javascript1.2"">self.opener.location.reload();</script>" & vbNewLine

end sub