<%
'#################################################################################
'## NET IPGATE v2.2.8 Orig Idea by alex042@aol.com(c)Aug 2002, 
'## rewritten by www.gpctexas.net Patrick@gpctexas.net March 31, 2004
'#################################################################################


cookiename="IPGate" 'must change for each forum you host on the same domain!
REDIRECT_BAN="ipgate_banned.asp"
REDIRECT_LCK="ipgate_lockdown.asp"
REDIRECT_NOA="ipgate_noaccess.asp"

If (Request.ServerVariables("HTTP_CLIENT_IP") <> "") and (lcase(Request.ServerVariables("HTTP_CLIENT_IP")) <> "unknown") then
   userip=Request.ServerVariables("HTTP_CLIENT_IP")
else
   if (Request.ServerVariables("HTTP_X_FORWARDED_FOR") <> "") and (lcase(Request.ServerVariables("HTTP_X_FORWARDED_FOR")) <> "unknown") then
      userip=Request.ServerVariables("HTTP_X_FORWARDED_FOR")
   else
      if (Request.ServerVariables("REMOTE_ADDR") <> "") and (lcase(Request.ServerVariables("REMOTE_ADDR")) <> "unknown")  then
         userip=Request.ServerVariables("REMOTE_ADDR")
      else
         userip="999.999.999.999"
      end if
   end if
end if

pagereq=Request.ServerVariables("Path_Info")
PathLen = InStrRev(pagereq,"/",-1)
pagreq = lcase(Right(pagereq,(len(pagereq)-PathLen)))
	
userhost=request.servervariables("REMOTE_HOST")
userdate=DateToStr(strForumTimeAdjust)
pageqryd=Request.ServerVariables("QUERY_STRING")
'pagreq=request.servervariables("SCRIPT_NAME")
pagereqtemp=pagreq & "?" & pageqryd 
getthecookie=Request.Cookies(trim(cookiename))
notindb=1
FoundIP=0
FoundName=0
	
pagename=pagreq
if pageqryd <> "" and Len(pagereqtemp) <= 245 then 'database field length check for access db users with a little leway
	pagreq=pagereqtemp
end if

if strIPGateBan = 1 then
	'get db records
	Set rs1 = Server.CreateObject("ADODB.Recordset")
	StrSql = "SELECT * FROM " & strTablePrefix & "IPLIST"	
	rs1.Open StrSql, strConnString
	
	do until (rs1.eof)

	dbrecord = rs1("IPLIST_STARTIP") & "."
	dbrecordarr = split(dbrecord,".")
	useriparr = userip & "."
	useriparr = split(userip,".")

		
	' FIND AN EXACT MATCH
	IF (rs1("IPLIST_STARTIP") = userip) then
		FoundIP = 1               
	End IF	 

	' Find 3 octet match
	' Requires a check to make sure 4 octet is actually empty, 
	' 123.123.123.xx
	IF FoundIP <> 1 and (dbrecordarr(3) = "")  and ((dbrecordarr(0) =  useriparr(0)) and (dbrecordarr(1) =  useriparr(1)) and (dbrecordarr(2) =  useriparr(2))) THEN 
		FoundIP = 1
	End IF	

	' Find 2 octet match
	' Requires a Check to make sure the 3rd octet is actually empty
	' 123.123.xx.xx
	IF FoundIP <> 1 and (dbrecordarr(2) = "") and ((dbrecordarr(0) =  useriparr(0)) and (dbrecordarr(1) =  useriparr(1))) then 
		FoundIP = 1          
	End IF

	' Find name match
	IF lcase(rs1("IPLIST_MEMBERID")) = lcase(strDBNTUsername) then 
		FoundName = 1          
	End IF
	
	' Expire the cookie
	if ((FoundName = 1) or (FoundIP = 1)) and rs1("IPLIST_STATUS") = 3 then
		call writethecookie ("Expired", DateAdd("d",-14,Date)) 'sets cookie date today-14 days thus expiring it
	end if

	if (FoundName = 1 or FoundIP = 1) and (rs1("IPLIST_STATUS") <> 3) and ((userdate >= rs1("IPLIST_STARTDATE")) and (userdate <= rs1("IPLIST_ENDDATE"))) then 
		if rs1("IPLIST_STATUS") = 0 and mlev < 4 then
			if strIPGateCok = 1 then
				call writethecookie ("Banned", ChkDate(rs1("IPLIST_ENDDATE"), " " ,true))
			end if
			if strIPGatetyp = 0 then
				if strIPGatelog = 1 then
			    	notindb=0
			    	call loguser()
			    end if
			end if
			call banned()
		else
			if rs1("IPLIST_STATUS") = 1 then
				if strIPGateCok = 1 then
					call writethecookie ("Watched", ChkDate(rs1("IPLIST_ENDDATE"), " " ,true))
				end if
				if strIPGatetyp = 0 then
					if strIPGatelog = 1 then
			    		notindb=0
			    		call loguser()
			    	end if
				end if
				call warnuser()
			else
				if rs1("IPLIST_STATUS") = 2 and mlev < 4 then
					Set rs3 = Server.CreateObject("ADODB.Recordset")
					PageSql = "SELECT * FROM " & strTablePrefix & "PageKeys"
	
					rs3.Open PageSql, strConnString
					do until (rs3.eof)
					
						if lcase(rs3("PAGEKEYS_PAGEKEY")) = lcase(pagename) then
						   call writethecookie ("Blocked", ChkDate(rs1("IPLIST_ENDDATE"), " " ,true))
						   call noaccess()
						end if
					
					rs3.MoveNext
    				Loop
    				checkconn(rs3)
					nullconn(rs3)
					if strIPGatetyp = 0 then
						if strIPGatelog = 1 then
			    			notindb=0
			    			call loguser()
			    		end if
					end if
				end if
			end if		
		end if	
	end if
		
	rs1.MoveNext
    Loop
    checkconn(rs1)
	nullconn(rs1)

	'not located in db at this point, start check for cookies
	if strIPGateBan = 1 then
		if notindb=1 then 
			if strIPGatecok = 1 then
		   		if getthecookie = "Banned" and mlev < 4 then
		      		if strIPGatetyp = 0 then
						if strIPGatelog = 1 then
			    			call loguser()
			    		end if
			  		end if
		      		call banned()
		   		else
		   			if getthecookie = "Watched" then
		      			if strIPGatetyp = 0 then
							if strIPGatelog = 1 then
			    				call loguser()
			    			end if
						end if
		      			call warnuser()
		      		else
		   		   		if getthecookie = "Blocked" and mlev < 4  then
		   		      		Set rs3 = Server.CreateObject("ADODB.Recordset")
					  		PageSql = "SELECT * FROM " & strTablePrefix & "PageKeys"
	
  					  		rs3.Open PageSql, strConnString
 					  		do until (rs3.eof)
					
							if lcase(rs3("PAGEKEYS_PAGEKEY")) = lcase(pagename) then
						   		call noaccess()
							end if
					
					  		rs3.MoveNext
    				  		Loop
    				  		checkconn(rs3)
					  		nullconn(rs3)
					  		if strIPGatetyp = 0 then
					   	 		if strIPGatelog = 1 then
			    		 			call loguser()
			    		 		end if
					  		end if
				   		end if
		   			end if
	 			end if
			end if
		end if
	end if
end if


if StrIPGateTyp = 1 and strIPGateBan = 1 then
 call loguser()
end if

if strIPGateLck = 1 and mlev < 4 and strIPGateBan = 1 then
  call lockdown()
end if

' functions ******************************************************

sub loguser()
	
	Set rs2 = Server.CreateObject("ADODB.Recordset")
	StrSql = "INSERT into " & strTablePrefix & "IPLOG (IPLOG_MEMBERID, IPLOG_IP, IPLOG_PATHINFO, IPLOG_DATE) "
	StrSql = StrSql & "values ('" & strDBNTUserName & "','" & userip & "','" & pagreq & "','" & userdate & "')"
	rs2.Open StrSql, strConnString 
	if rs2.State = 1 then rs2.Close
	set rs2 = nothing	
	
end sub

sub writethecookie (cookietype, cookiedate)
	
	if strIPGateCok = 1  then
	    Response.Cookies(trim(cookiename))=cookietype
	    Response.Cookies(trim(cookiename)).Expires = cookiedate
	end if

end sub

function checkconn (conn)
	if conn.State = 1 then conn.Close

end function

function nullconn (conn)
	if conn.State = 0 then set conn=nothing

end function


sub banned ()
	Select Case StrIPGateMet
	Case 0
		response.write "<br><BR><BR><BR><p align=center><b>" & StrIPGateMsg & "</b></p><br><BR><BR><BR>"
		%><!--#INCLUDE file="inc_footer.asp"--><%
		response.end

	Case 1
		Response.Redirect REDIRECT_BAN
	end select

		
	end sub
	
sub lockdown ()
	Select Case StrIPGateMet
	Case 0
		response.write "<br><BR><BR><BR><p align=center><b>" & StrIPGateLkMsg & "</b></p><br><BR><BR><BR>" 
		%>
<!--#INCLUDE file="inc_footer.asp"--><%
		response.end

	Case 1
		Response.Redirect REDIRECT_LCK
	end select

		
end sub

sub noaccess ()
	Select Case StrIPGateMet
	Case 0
		response.write "<br><BR><BR><BR><p align=center><b>" & strIPGateNoAcMsg & "</b></p><br><BR><BR><BR>" 
		%>
<!--#INCLUDE file="inc_footer.asp"--><%
	response.end
	Case 1
		Response.Redirect REDIRECT_NOA
	end select

		
end sub

sub warnuser()
	response.write "<br><center><b>Message:</b> " & StrIPGateWarnMsg & "</center>"		
end sub


%>