bolOverride = chkAUPermissions(strAUAnonOverride)
bolPanel = chkAUPermissions(strAUPAllow)
bolAUPage = chkAUPermissions(strAUAllow)

'## Ls3k - Before we can do anything we need to get rid of those slackers who have left ;)
deleteInactiveUsers()

'## Ls3k - Lest first deal with members logged in - for them we need to join with the members table.
intTotalActiveUsers = 0
intActiveMembers = 0
intActiveAnonMembers = 0
intActiveGuests = 0

strSql = "SELECT ME.MEMBER_ID, ME.M_NAME, ME.M_AUHIDE, ME.M_LEVEL " & _
         "FROM " & strTablePrefix & "ACTIVE_USERS AU, " & strMemberTablePrefix & "MEMBERS ME " & _
         "WHERE AU.MEMBER_ID = ME.MEMBER_ID"
set rsAM = my_conn.execute (strSql)
if rsAM.EOF or rsAM.BOF then
  rsAM.close
  set rsAM = nothing
else
  do until rsAM.EOF
    intTotalActiveUsers = intTotalActiveUsers + 1
    if (rsAM("M_AUHIDE")="1" or isNull(rsAM("M_AUHIDE"))) or strAUAnon = 0 or bolOverride then
      intActiveMembers = intActiveMembers + 1
      if strActiveMemberList <> "" then
        strActiveMemberList = strActiveMemberList & " | " & VBNewLine
      end if
      if strUseExtendedProfile then
        strActiveMemberList = strActiveMemberList & "<a href=""pop_profile.asp?mode=display&id="& rsAM("MEMBER_ID") & """>"
      else
        strActiveMemberList = strActiveMemberList & "<a href=""JavaScript:openWindow2('pop_profile.asp?mode=display&id=" & rsAM("MEMBER_ID") & "')"">"
      end if
      strActiveMemberList = strActiveMemberList & "<font color=""" & strDefaultFontColor & """>"
      if rsAM("M_LEVEL") = 2 then
        strActiveMemberList = strActiveMemberList & "<font color=""" & strAUModColor & """>"
      elseif rsAM("M_LEVEL") = 3 then
        strActiveMemberList = strActiveMemberList & "<font color=""" & strAUAdminColor & """>"
      end if
      strActiveMemberList = strActiveMemberList & rsAM("M_NAME")
      if rsAM("M_LEVEL") = 2 or rsAM("M_LEVEL") = 3 then
        strActiveMemberList = strActiveMemberList & "</font>"
      end if
      strActiveMemberList = strActiveMemberList & "</font>"
      strActiveMemberList = strActiveMemberList & "</a>"
    else
      intActiveAnonMembers = intActiveAnonMembers + 1
    end if
	rsAM.movenext
  loop
  rsAM.close
  set rsAM = nothing
end if

'## Ls3k - Now lets count those peskey guests.
strSql = "SELECT COUNT(AU_IP) AS CNT FROM " & strTablePrefix & "ACTIVE_USERS WHERE MEMBER_ID = -1"
set rs = my_conn.execute (strSql)
intActiveGuests = rs("CNT")
rs.close
set rs = nothing
intTotalActiveUsers = intTotalActiveUsers + intActiveGuests


response.write     "          <font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """>" & VBNewLine & _
                   "          " & fLang(strLangMOD_Ls3kAU_00100) & ": "

if intActiveMembers > 0 then
	  response.write strActiveMemberList & VBNewLine
	else
	  response.write fLang(strLangMod_Ls3kAU_00110) & VBNewLine
	end if
	%>