<!--#include file="config.asp"-->
<!--#include file="inc_func_common.asp" -->
<%
'---------------------------------------------------
' Simple Slash MOD
' Simply displays the last intTopicCount topics
' From ForumID (Use ForumID = "ANY" for all Forums)
'---------------------------------------------------

Const intTopicCount = 5
Const ForumID = "ANY"
Const CharsToDisplay = 200

'------------
' Get Topics
'------------
strSql = "SELECT "
strSql = strSql & strTablePrefix & "TOPICS.TOPIC_ID, "
strSql = strSql & strTablePrefix & "TOPICS.T_SUBJECT, "
strSql = strSql & strTablePrefix & "TOPICS.T_MESSAGE, "
strSql = strSql & strTablePrefix & "TOPICS.T_DATE, " 
strSql = strSql & strTablePrefix & "TOPICS.T_AUTHOR, "
strSql = strSql & strTablePrefix & "MEMBERS.MEMBER_ID, "
strSql = strSql & strTablePrefix & "MEMBERS.M_NAME "
strSql = strSql & " FROM ((" & strTablePrefix & "FORUM " 
strSql = strSql & "INNER JOIN " & strTablePrefix & "TOPICS ON " 
strSql = strSql & strTablePrefix & "FORUM.FORUM_ID = " 
strSql = strSql & strTablePrefix & "TOPICS.FORUM_ID) " 
strSql = strSql & "INNER JOIN " & strTablePrefix & "MEMBERS ON "
strSql = strSql & strTablePrefix & "TOPICS.T_AUTHOR = " 
strSql = strSql & strTablePrefix & "MEMBERS.MEMBER_ID) "
If ForumID <> "ANY" Then strSql = strSql & " WHERE " & strTablePrefix & "TOPICS.FORUM_ID = " & ForumID
strSql = strSql & " ORDER BY " & strTablePrefix & "TOPICS.T_DATE DESC "
strSql = strSql & "LIMIT " & intTopicCount
Dim objConn, objRS
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open strConnString
Set objRS = objConn.Execute(strSQL)

Response.Write	"      <table border=""0"" cellspacing=""1"" cellpadding=""0"" bgcolor=""" & strTableBorderColor & """ width=""100%""><tr><td>" & vbNewline
Response.Write	"      <table border=""0"" width=""100%"" cellspacing=""0"" cellpadding=""2"" align=""center"" bgcolor=""" & strForumCellColor & """>" & vbNewline
Response.Write	"      <tr><td align=""center"" background=""imgs/headbg.gif"" bgcolor=""" & strHeadCellColor & """ colspan=""3""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """ color=""" & strHeadFontColor & """>Latest Topics</font></TD></tr>" & vbNewline

While Not objRS.EOF
  strSQL = "SELECT COUNT(*) FROM FORUM_REPLY WHERE TOPIC_ID = " & objRS("TOPIC_ID")
  Set objRS2 = objConn.Execute(strSQL)
  Response.Write "<tr><td background=""imgs/catbg.gif"" bgcolor=""" & strCategoryCellColor & """ colspan=""3"" align=""center""><font face=""" & strDefaultFontFace & """ size=""" & strDefaultFontSize & """> <B>" & ChkString(objRS("T_SUBJECT"),"title") & "</B></font></td></tr>"
  Response.Write "<tr><td background=""imgs/catbg.gif"" bgcolor=""" & strCategoryCellColor & """ align=""center"" rowspan=""3"" valign=""top""><font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """> Posted by: <br><b>" & objRS("M_NAME") & "</b><br> on <br>" & strToDate(objRS("T_DATE")) & "</font></td>"
  Response.Write "<td bgcolor=""" & strForumCellColor & """><font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """ color=""" & strForumFontColor & """><br>  " & Left(RemoveHTML(FormatStr(objRS("T_MESSAGE"))),CharsToDisplay) & "...</font></td></tr>"
  Response.Write "<tr><td bgcolor=""" & strForumCellColor & """ colspan=""3""> <a href='topic.asp?TOPIC_ID=" & objRS("TOPIC_ID") & "'><font face=""" & strDefaultFontFace & """ size=""" & strFooterFontSize & """>More >></a>  Replies(" & objRS2(0) & ")</font></td></tr>"
  Response.Write "<tr><td bgcolor=""" & strForumCellColor & """ colspan=""3"" height=""5""></td></tr>"
  objRS.MoveNext()
Wend

response.write  "</table></td></tr></table>" & vbNewLine
objRS2.Close()
Set objRS2 = Nothing
objRS.Close()
Set objRS = Nothing
objConn.Close()
Set objConn = Nothing


Response.End

Function RemoveHTML( strText )
  Dim TAGLIST
  TAGLIST=";A;B;IMG;CENTER;FONT;PRE;BLOCKQUOTE;"
    
  Dim nPos1
  Dim nPos2
  Dim nPos3
  Dim strResult
  Dim strTagName
  Dim bRemove
  Dim bSearchForBlock
  
  nPos1 = InStr(strText, "<")
  Do While nPos1 > 0
    nPos2 = InStr(nPos1 + 1, strText, ">")
    If nPos2 > 0 Then
      strTagName = Mid(strText, nPos1 + 1, nPos2 - nPos1 - 1)
      strTagName = Replace(Replace(strTagName, vbCr, " "), vbLf, " ")
      nPos3 = InStr(strTagName, " ")
      If nPos3 > 0 Then
        strTagName = Left(strTagName, nPos3 - 1)
      End If
         
      If Left(strTagName, 1) = "/" Then
        strTagName = Mid(strTagName, 2)
        bSearchForBlock = False
      Else
        bSearchForBlock = True
      End If
           
      If InStr(1, TAGLIST, ";" & strTagName & ";", vbTextCompare) > 0 Then
        bRemove = True
        
        If bSearchForBlock Then
        
          If InStr(1, BLOCKTAGLIST, ";" & strTagName & ";", vbTextCompare) > 0 Then
            nPos2 = Len(strText)
            nPos3 = InStr(nPos1 + 1, strText, "</" & strTagName, vbTextCompare)
        
            If nPos3 > 0 Then
              nPos3 = InStr(nPos3 + 1, strText, ">")
            End If
                      
            If nPos3 > 0 Then
              nPos2 = nPos3
            End If
            
          End If
          
        End If
        
      Else
        bRemove = False
      End If
          
      If bRemove Then
        strResult = strResult & Left(strText, nPos1 - 1)
        strText = Mid(strText, nPos2 + 1)
      Else
        strResult = strResult & Left(strText, nPos1)
        strText = Mid(strText, nPos1 + 1)
      End If
    Else
      strResult = strResult & strText
      strText = ""
    End If
      
    nPos1 = InStr(strText, "<")
  Loop
  strResult = strResult & strText    
  RemoveHTML = strResult
End Function  
%>