DECLARE
	@ArchiveForumID int,
	@Error bit

SET
	@ArchiveForumID = 3
SET
	@Error = 0

BEGIN TRANSACTION UnArchive

SET IDENTITY_INSERT FORUM_TOPICS ON

INSERT INTO
	FORUM_TOPICS
		(
		CAT_ID,
		FORUM_ID,
		TOPIC_ID,
		T_STATUS,
		T_MAIL,
		T_SUBJECT,
		T_MESSAGE,
		T_AUTHOR,
		T_REPLIES,
		T_UREPLIES,
		T_VIEW_COUNT,
		T_LAST_POST,
		T_DATE,
		T_LAST_POSTER,
		T_IP,
		T_LAST_POST_AUTHOR,
		T_LAST_POST_REPLY_ID,
		T_ARCHIVE_FLAG,
		T_LAST_EDIT,
		T_LAST_EDITBY,
		T_STICKY,
		T_SIG,
		T_EVENT_DATE,
		T_ISEVENT
		)
	SELECT
		CAT_ID,
		FORUM_ID,
		TOPIC_ID,
		1,   
		T_MAIL,
		T_SUBJECT,
		T_MESSAGE,
		T_AUTHOR,
		T_REPLIES,
		T_UREPLIES,
		T_VIEW_COUNT,
		T_LAST_POST,
		T_DATE,
		T_LAST_POSTER,
		T_IP,
		T_LAST_POST_AUTHOR,
		T_LAST_POST_REPLY_ID,
		T_ARCHIVE_FLAG,
		T_LAST_EDIT,
		T_LAST_EDITBY,
		T_STICKY,
		T_SIG,
		T_EVENT_DATE,
		T_ISEVENT
	FROM
		FORUM_A_TOPICS
	WHERE
		FORUM_ID = @ArchiveForumID

IF
	@@Error <> 0
BEGIN
	SET	@Error = 1
	PRINT 'UnArchive Failed at FORUM_TOPICS'
END
ELSE
BEGIN
	PRINT 'UnArchive FORUM_TOPICS Completed'
END


SET IDENTITY_INSERT FORUM_TOPICS OFF
SET IDENTITY_INSERT FORUM_REPLY ON

INSERT INTO
	FORUM_REPLY
		(
		CAT_ID,
		FORUM_ID,
		TOPIC_ID,
		REPLY_ID,
		R_MAIL,
		R_AUTHOR,
		R_MESSAGE,
		R_DATE,
		R_IP,
		R_STATUS,
		R_LAST_EDIT,
		R_LAST_EDITBY,
		R_SIG
		)
	SELECT
		CAT_ID,
		FORUM_ID,
		TOPIC_ID,
		REPLY_ID,
		R_MAIL,
		R_AUTHOR,
		R_MESSAGE,
		R_DATE,
		R_IP,
		R_STATUS,
		R_LAST_EDIT,
		R_LAST_EDITBY,
		R_SIG
	FROM
		FORUM_A_REPLY
	WHERE
		FORUM_ID = @ArchiveForumID

IF
	@@Error <> 0
BEGIN
	SET	@Error = 1
	PRINT 'UnArchive Failed at FORUM_REPLY'
END
ELSE
BEGIN
	PRINT 'UnArchive FORUM_REPLY Completed'
END

SET IDENTITY_INSERT FORUM_REPLY OFF

DELETE
FROM
	FORUM_A_TOPICS
WHERE
	FORUM_ID = @ArchiveForumID

PRINT 'Delete FORUM_A_TOPICS Completed'

DELETE
FROM
	FORUM_A_REPLY
WHERE
	FORUM_ID = @ArchiveForumID

PRINT 'Delete FORUM_A_REPLY Completed'

-- Update FORUM_TOTALS Counts
UPDATE
	FORUM_TOTALS
SET
	P_COUNT = (
		SELECT
			COUNT(*)
		FROM
			FORUM_REPLY
		),
	P_A_COUNT = (
		SELECT
			COUNT(*)
		FROM
			FORUM_A_REPLY
		),
	T_COUNT = (
		SELECT
			COUNT(*)
		FROM
			FORUM_TOPICS
		),
	T_A_COUNT = (
		SELECT
			COUNT(*)
		FROM
			FORUM_A_TOPICS
		)

PRINT 'Update Counts for FORUM_TOTALS Completed'

-- Update Specific Forum Counts
UPDATE
	FORUM_FORUM
SET
	F_TOPICS = (
		SELECT
			COUNT(*)
		FROM
			FORUM_TOPICS
		WHERE
			FORUM_ID = @ArchiveForumID
		),
	F_COUNT = (
		SELECT
			COUNT(*)
		FROM
			FORUM_REPLY
		WHERE
			FORUM_ID = @ArchiveForumID
		),
	F_A_TOPICS = (
		SELECT
			COUNT(*)
		FROM
			FORUM_A_TOPICS
		WHERE
			FORUM_ID = @ArchiveForumID
		),
	F_A_COUNT = (
		SELECT
			COUNT(*)
		FROM
			FORUM_A_REPLY
		WHERE
			FORUM_ID = @ArchiveForumID
		)
WHERE
	FORUM_ID = @ArchiveForumID

PRINT 'Update Counts for Specific Forum Completed'

IF
	@Error = 1
BEGIN
	ROLLBACK TRANSACTION UnArchive
	PRINT ''
	PRINT 'UnArchive Failed, all Transactions Rolled Back to Original State'
END
ELSE
BEGIN
	COMMIT TRANSACTION UnArchive
	PRINT ''
	PRINT 'Entire UnArchive Process Completed Successfully'
END
								

GO