I am just now adding my mods to the 3.4 version and ran into a few problems.
Most of the sql queries use GetRows to store the records in an array. Then they are stored in variables according to thier positions in the array.
When I add a new column to retrieve in the sql query, I also have to modify the variables that point to each record in the array, to accomodate the new field. That means, updating each position for each field in the array.
This would be easy enough when only one mod is modifying the sql query. But when more than one mod adds thier own field, finding the position of each record in the array could get confusing. Even for me.
Is this the only way to add a new column to an sql query using GetRows?
Just add them to the end whenever possible. The only place this won't work well is post.asp and topic.asp which pulls back the message (ie the text/memo) fields which need to be last in the query to work well.
Function GetFieldPos(prs,pstrField)
GetFieldPos = -1
For intC = 0 to prs.Fields.Count - 1
if ucase(prs.Fields(intC).Name) = ucase(pstrField) then
GetFieldPos = intC
exit for
end if
Next
End Function
Similar Approach as posted by pweighill. Store the field names in an array and then call the function FieldPos to get the field position in the array. Following is an example with code abstarcts from topic.asp
Add the statements in red below before calling the GetRows method
dim intIndex, FieldsArray()
Redim FieldsArray(rsReplies.Fields.Count-1)
intIndex = 0
For each fld in rsReplies.Fields
FieldsArray(intIndex)= fld.Name
intIndex = intIndex + 1
next
arrReplyData = rsReplies.GetRows(strPageSize)
rM_NAME = FieldPos("M_NAME")
rM_RECEIVE_EMAIL = FieldPos("M_RECEIVE_EMAIL")
rM_AIM = FieldPos("M_AIM")
rM_ICQ = FieldPos("M_ICQ")
rM_MSN = FieldPos("M_MSN")
rM_YAHOO = FieldPos("M_YAHOO")
rM_TITLE = FieldPos("M_TITLE")
rMEMBER_ID = FieldPos("MEMBER_ID")
rM_HOMEPAGE = FieldPos("M_HOMEPAGE")
rM_LEVEL = FieldPos("M_LEVEL")
rM_POSTS = FieldPos("M_POSTS")
rM_COUNTRY = FieldPos("M_COUNTRY")
rMOD_FIELD = FieldPos("MOD_FIELD")
rREPLY_ID = FieldPos("REPLY_ID")
rFORUM_ID = FieldPos("FORUM_ID")
rR_AUTHOR = FieldPos("R_AUTHOR")
rTOPIC_ID = FieldPos("TOPIC_ID")
rR_MESSAGE = FieldPos("R_MESSAGE")
rR_LAST_EDIT = FieldPos("R_LAST_EDIT")
rR_LAST_EDITBY = FieldPos("R_LAST_EDITBY")
rR_SIG = FieldPos("R_SIG")
rR_STATUS = FieldPos("R_STATUS")
rR_DATE = FieldPos("R_DATE")
if CanShowSignature = 1 then
rM_SIG = FieldPos("M_SIG")
end if
for iForum = 0 to iReplyCount
Reply_MemberName = arrReplyData(rM_NAME, iForum)
...
...
next
Alternatively, it can also be done as below:
for iForum = 0 to iReplyCount
Reply_MemberName = arrReplyData(FieldPos("M_NAME"), iForum)
...
...
next
function FieldPos(strFieldname)
dim index
for index = lbound(FieldsArray) to ubound(FieldsArray)
if Ucase(FieldsArray(index)) = Ucase(strFieldName) then FieldPos = index : exit for
next
end function
pweighill and GauravBhabu, I am not kidding but you guys must live and breath this code. I thought I have seen the worst when persons dream about the code but you guys past that. How many posts I have seen you guys dish out new subroutines and functions like it was a piece of pie? You guys amaze me.
Anyways, the code you guys provide looks good. But wouldn't that have to be something in the base code to do that? I mean, I am sure many other mods need to make the same change. I can't toally re-do that piece of code in the files for my mods. Users will get confused when it comes to adding other mods to it.
Or maybe we could manage to get it into the base code?
But I guess I would have to do it the original way for now. Thanks GB and pweighill.
Topic Locked
Posted - 27 September 2002 : 03:50:12
