quote:

---

Yes, we're going to implement this behavour. All works fine except the use of NT Groups...

---

quote:

---

In our implementation we modified register.asp to retrieve user-information from active directory, when a user (nt-authenticated with AutoLogon enabled) enteres the forum for the first time. This way the fields name, lastname and email are populated from AD. Currently there are two problems:

1. AD root is hard coded into the asp-file. It would be better, if a configuration option could be integrated to switch on AD access und specify parameters like AD root and searchbase.

2. AD information is only retrieved during authentication. If AD information changes (for example the email adress) the profile in the forum is not updated.

Ralf

---

Dim oADUser
Dim sADUser
 
Set oADUser = Nothing
sADUser = ""
 
Const LDAP_STRING = "LDAP://your.domain.com/"
Const LDAP_SEARCH = "DC=your,DC=domain,DC=com"
 
Function findADUser(rsID)
 
    Dim oDB
    Dim oRS
    
    Dim oUser
 
    Set oDB = CreateObject("ADODB.Connection")
    oDB.Provider = "ADsDSOObject"
    oDB.Open "Active Directory Provider"
 
    Set oRS = oDB.Execute("select AdsPath from '" & LDAP_STRING & LDAP_SEARCH & "' where name='" & rsID & "' and objectclass='user' and objectclass<>'computer'")
    
    If oRS.EOF Then
        Set oUser = Nothing
    Else
        Set oUser = GetObject(oRS("AdsPath"))
    End If
 
    Set findAdUser = oUser
    
    Set oUser = Nothing
    Set oRS = Nothing
    Set oDB = Nothing
 
End Function
 
Sub getADUser()
    If (oADUser Is Nothing and not (sADUser = strDBNTUserName)) Then
        Set oADUser = findADUser(strDBNTUserName)
        sADUser = strDBNTUserName
    End If
End Sub
 
Function getADField(sFieldName)
    On Error Resume Next
    getADUser()
    sValue = oADUser.Get(sFieldName)
    If err.number = 0 Then
        getADField = sValue
    Else
        getADField = ""
    End If
    On Error Goto 0
End Function
 
Function getADEmail()
    sEmail = getADField("mail")
    if (sEmail = "") Then
        sEmail = strDBNTUserName & "@local"
    end if
    getADEmail = sEmail
End Function
 
Function getADFirstName()
    getADFirstName = getADField("givenName")
End Function
 
Function getADLastName()
    getADLastName = getADField("sn")
End Function
 
Function getADFullName()
    If (getADLastName = "" or getADFirstName = "") Then
        fullName = getADField("description")
        If (fullName = "") Then
            fullName = getADField("displayName")
            If (fullName = "") Then
                fullName = sADUser
            End If
        End If
    Else
        fullName = getADLastName() & ", " & getADFirstName
    End If
    getADFullName = fullName
End Function
 
%>

quote:

---

2. AD information is only retrieved during authentication. If AD information changes (for example the email adress) the profile in the forum is not updated.

---

quote:

---

Ok. Here is my inc_activedirectory.asp
You have to customize the consts LDAP_STRING and LDAP_SEARCH.
I included the file in register.asp and used the provided functions
to initialize the corresponding fields with values from the AD.

Ralf

---

quote:

---

Thanks for listing that code, i've popped in onto the forums (with correct ldap names), but am unsure of where to add the "getademail" function to actually pull the email address from the active directory.

---

quote:

---

I haven't integrated AD into snitz (yet), but seems like this could be either an admin option to update email addresses -or- an option in the user's profile to grab their new address. The only problem would be if the user's CN was changed as well.

---

quote:

---

I included inc_activedirectory.asp in register.asp and edited the lines
for populating the default values in the members table (near line 211).

Ralf

---