<%
GetPopMail "USERNAME", "PASSWORD", "pop.mail.yahoo.com", 110, false
%>

<%
Function GetPopMail(ByVal usr, ByVal pass, ByVal mailserver, _
    ByVal mailport, byVal bShowHeaders)
	'declare variables
	Dim pop, headers, i, messages, ct, message
	'create jmail pop3 object
	Set pop = CreateObject("JMail.POP3")
	'connect to account
	pop.Connect usr, pass, mailserver, mailport
	'download mail headers
	pop.DownloadHeaders
	'download mail messages
	pop.DownloadMessages
	'get handle to the messages object
	Set messages = pop.Messages
	'count of messages retrieved
	ct = messages.count - 1
	'if there's messages...
	if ct >= 1 then
		'loop through messages
		for i = 1 to ct
			'get handle to message object
			Set message = messages.item(i)
			'show headers or whole email...
			if bShowHeaders then
				'print header
				Response.Write( message.Text & "<BR><BR>")
			else
				'print subject and body
				Response.Write( "<B>" & _
												message.subject & "</B><BR>" )
				Response.Write( message.body & _
                                    "<BR><BR>" )
			end if
			'free message handle
			Set message = nothing
		next
	else
		'no messages
		Response.Write( "no messages on " & mailserver )
	end if
	'disconnect from server
	pop.disconnect
	'release messages handle
	Set messages = Nothing
	'free jmail pop3 object
	Set pop = Nothing
End Function
%>